Запись в ячейки Excel со сдвигом

const
  //Адрес левой верхней ячейки в области данных таблицы (т. е., прямо под шапкой таблицы).
  gAddr = 'A9';
 
var
  //Ссылка на интерфейс рабочего листа в книге MS Excel.
  gExSh : Variant;
 
procedure TForm1.Button7Click(Sender: TObject);
const
  //Идентификатор типа ячейки в диапазоне - последняя (справа внизу) ячейка диапазона.
  xlCellTypeLastCell = 11;
  //Вид линии.
  xlContinuous = 1;
  //Расположение линии.
  xlInsideVertical = 11;
  //Толщина линий.
  xlMedium = -4138;
  xlThick = 4;
  xlThin = 2;
  //Сдвиг вниз.
  xlShiftDown = -4121;
var
  exApp, exBook, exCell, exRng, exComm : Variant;
  i, RowE, Col, Offs : Integer;
  Od : TOpenDialog;
  S : String;
begin
  //Проверка подключения к БД.
  if not ADOQuery1.Active then begin
    MessageBox(0, 'Таблица закрыта. Действие отменено.'
      ,'Отмена', MB_OK + MB_ICONWARNING + MB_APPLMODAL);
    Exit;
  end;
  //Проверка, выбрана ли запись.
  if ADOQuery1.Eof then begin
    MessageBox(0, 'Запись не выбрана. Действие отменено.'
      ,'Отмена', MB_OK + MB_ICONWARNING + MB_APPLMODAL);
    Exit;
  end;
  //Проверка, есть ли подключение к MS Excel.
  if not VarIsClear(gExSh) then
  try
    S := gExSh.Name;
  except
    VarClear(gExSh);
  end;
  //Если подключения к Excel нет, то запускаем диалог открытия раб. книги Excel.
  if VarIsClear(gExSh) then begin
    Od := OpenDialog1; //OpenDialog1 уже должен быть на форме.
    if Od.InitialDir = '' then
      Od.InitialDir := ExtractFilePath( ParamStr(0) );
    if not Od.Execute then Exit;
    if not FileExists(Od.FileName) then begin
      MessageBox(0, 'Файл с заданным именем не найден. Действие отменено.'
        ,'Файл не найден', MB_OK + MB_ICONEXCLAMATION + MB_APPLMODAL);
      Exit;
    end;
    //Попытка подключиться к корневому объекту MS Excel.
    try
      exApp := CreateOleObject('Excel.Application');
    except
      MessageBox(0, 'Не удалось запустить MS Excel. Действие отменено.',
        'Ошибка', MB_OK + MB_ICONERROR + MB_APPLMODAL);
      Exit;
    end;
    //Делаем видимым окно MS Excel.
    exApp.Visible := True;
    //Открываем файл рабочей книги.
    exBook := exApp.WorkBooks.Open(FileName:=Od.FileName);
    //Получаем ссылку на ВТОРОЙ лист рабочей книги.
    if exBook.Worksheets.Count < 2 then begin
      MessageBox(0, 'В книге нет второго листа! Действие отменено.',
        'Ошибка', MB_OK + MB_ICONERROR + MB_APPLMODAL);
      Exit;
    end;
    gExSh := exBook.Worksheets[2];
  end;
 
  gExSh.Application.ScreenUpdating := False;
  try
    //Верхняя левая ячейка в области данных таблицы на листе MS Excel.
    exCell := gExSh.Range[gAddr];
 
    //Номер нижней занятой строки для всего используемого диапазона на листе Excel.
    RowE := gExSh.UsedRange.SpecialCells(xlCellTypeLastCell).Row;
    //Поиск метки последней строки и определение смещения до этой ячейки.
    Col := exCell.Column;
    Offs := -1;
    for i := exCell.Row to RowE do begin
      exComm := gExSh.Cells[i, Col].Comment;
      if not VarIsClear(exComm) and (exComm.Text = 'end') then begin
        Offs := i - exCell.Row;
        Break;
      end;
    end;
 
    //Для всех строк, которые расположены ниже таблицы, высоты переносим
    //на 1 строку вниз.
    for i := RowE downto exCell.Row do
      gExSh.Cells[i + 1, 1].RowHeight := gExSh.Cells[i, 1].RowHeight;
 
    //Если метка найдена, то удаляем её и добавляем новую строку.
    if Offs > -1 then begin
      //Удаление метки.
      exCell.Offset[Offs, 0].ClearComments;
      //Добавление новой строки.
      exRng := gExSh.Range[exCell.Offset[Offs + 1, 0]
        ,exCell.Offset[Offs + 1, 0].Offset[0, 15]];
      exRng.Insert(xlShiftDown);
      //Заново определяем диапазон, так как при вызове Insert() диапазон меняется.
      exRng := gExSh.Range[exCell.Offset[Offs + 1, 0]
        ,exCell.Offset[Offs + 1, 0].Offset[0, 15]];
      //Оформление строки.
      //exCell.Offset[Offs + 1, 0].RowHeight := exCell.RowHeight;
      exRng.Borders.Weight := xlThin;
    end;
    //Записываем данные
    exCell.Offset[Offs + 1, 0] := ADOQuery1.Fields[0].AsString;
    exCell.Offset[Offs + 1, 5] := ADOQuery1.Fields[5].AsString;
    exCell.Offset[Offs + 1, 8] := ADOQuery1.Fields[8].AsString;
    //Устанавливаем метку конца данных.
    exCell.Offset[Offs + 1, 0].AddComment('end');
  finally
    gExSh.Application.ScreenUpdating := True;
  end;
end;

Od := OpenDialog1; //OpenDialog1 уже должен быть на форме.

    //Записываем данные
    exCell.Offset[Offs + 1, 0] := ADOQuery1.Fields[0].AsString;
    exCell.Offset[Offs + 1, 5] := ADOQuery1.Fields[5].AsString;
    exCell.Offset[Offs + 1, 8] := ADOQuery1.Fields[8].AsString;

    //Записываем данные
    exCell.Offset[Offs + 1, 0] := ADOQuery1.Fields[0].AsString;
    exCell.Offset[Offs + 1, 5] := ADOQuery1.Fields[1].AsString;
    exCell.Offset[Offs + 1, 8] := ADOQuery1.Fields[2].AsString;