Решение СЛАУ методом Зейделя

Uses CRT;
 
Const
     maxn = 10;
 
Type
    Data = Real;
    Matrix = Array[1..maxn, 1..maxn] of Data;
    Vector = Array[1..maxn] of Data;
 
 
Procedure vvod(n: Integer; var a: Matrix; var b: Vector);
Var
   i, j, r: Integer;
Begin
     ClrScr;
     r := WhereY;
     GotoXY(2, r);
     Write('A');
     For i := 1 to n do begin
         GotoXY(i * 6 + 2, r);
         Write(i);
         GotoXY(1, r + i + 1);
         Write(i:2);
     end;
     GotoXY((n + 1) * 6 + 2, r);
     Write('b');
     For i := 1 to n do begin
         For j := 1 to n do begin
             GotoXY(j * 6 + 2, r + i + 1);
             Read(a[i, j]);
         end;
         GotoXY((n + 1) * 6 + 2, r + i + 1);
         Read(b[i]);
     end;
End;
 
 
Procedure vivod(n :Integer; x: Vector);
Var
   i: Integer;
Begin
     For i := 1 to n do
         Writeln('x', i, ' = ', x[i]);
End;
 
 
 
Function Seidel(n: Integer; a: Matrix; b: Vector; var x: Vector; e: Data) :Boolean;
Var
   i, j: Integer;
   s1, s2, s, v, m: Data;
Begin
 
 
     For i := 1 to n do begin
 
         s := 0;
         For j := 1 to n do
             If j <> i then
                s := s + Abs(a[i, j]);
 
         If s >= Abs(a[i, i]) then begin
            Seidel := false;
            Exit;
         end;
 
     end;
 
     Repeat
 
         m := 0;
         For i := 1 to n do begin
 
 
             s1 := 0;
             s2 := 0;
             For j := 1 to i - 1 do
                 s1 := s1 + a[i, j] * x[j];
             For j := i to n do
                 s2 := s2 + a[i, j] * x[j];
 
             v := x[i];
             x[i] := x[i] - (1 / a[i, i]) * (s1 + s2 - b[i]);
 
             If Abs(v - x[i]) > m then
                m := Abs(v - x[i]);
 
         end;
 
     Until m < e;
 
     Seidel := true;
End;
 
Var
    n, i: Integer;
    a: Matrix;
    b, x: Vector;
    e: Data;
Begin
 
      Writeln('vvedite poradok matrici (max. 10)');
      Repeat
             Write('>');
             Read(n);
      Until (n > 0) and (n <= maxn);
      Writeln;
 
      Writeln('vvedite tochnost');
      Repeat
             Write('>');
             Read(e);
      Until (e > 0) and (e < 1);
      Writeln;
 
      Writeln('vvedite matricy');
      vvod(n, a, b);
      Writeln;
 
      For i := 1 to n do
          x[i] := 0;
 
    if  Seidel(n, a, b, x, e) then begin
      vivod(n, x);
      end
      else writeln('ne imeet reshenia');
      writeln('dla prodoljenia najmite vvod');
      readln;
 
End.