Считать последовательность игральных карт и занести их в массив множеств

 type 
    longstring = string[3]; // один символ на масть и два на карту (число 10 имеется ввиду)
    mast = (wini, kresti, bubi, hervi);
    karts = (six, seven, eight, nine, ten, valet, dama, corol, tuz);
    koloda = array [ mast, karts ] of longstring;

     repeat 
      readln(c); //c: char
     until c in['w','k','b','h'];

longstring = string[3]; // один символ на масть и два на карту (число 10 имеется ввиду)
koloda = array [ mast, karts ] of longstring;

 type 
      long = string[3];
      mast = (W, K, B, H);
      karts = (six, seven, eight, nine, ten, valet, dama, corol, tuz);
      kart = set of karts;
  const 
      kar : array [ karts ] of long = ('6','7','8','9','10','V','D','C','T');
   type 
       koloda = array [ mast ] of kart;
    var ko: koloda;

  type
    mast = (W, K, B, H);
    karts = (six, seven, eight, nine, ten, valet, dama, corol, tuz);
    kart = set of karts;
    koloda = array [mast] of kart;
   var ko: koloda; i : mast; j: karts;
procedure zapolnenie( var ko: koloda);
  begin
   for i:= w to h do
    for j:= six to tuz do
     ko [ i ]:= ko [ i ] + [ j ];
   end;

type
  TSuit = (ErrSuit,
    Hearts {черви}, Diamonds {бубны}, Clubs {трефи}, Spades {пики});
  TRank = (ErrRank,
    Ace, Two, Three, Four, Five, Six, Seven, Eight, Nine, Ten,
    Jack, Queen, King);
  TDeck = array [Hearts..Spades] of set of Ace..King;
 
const
  SuitStrings: array [TSuit] of string[5] = ('?',
    #3'ЧчHh', #4'БбDd', #5'ТтCc', #6'ПпSs');
  RankStrings: array [TRank] of string[4] = ('?',
    'ТтAa', '2', '3', '4', '5', '6', '7', '8', '9', '10',
    'ВвJj', 'ДдQq', 'КкKk');
 
function SuitToStr(s: TSuit): string;
begin
  SuitToStr:=SuitStrings[s][1];
end;
 
function RankToStr(r: TRank): string;
begin
  if r=Ten then RankToStr:=RankStrings[r] else RankToStr:=RankStrings[r][1];
end;
 
function StrToSuit(s: string): TSuit;
var i: TSuit;
begin
  StrToSuit:=ErrSuit;
  if s='' then Exit;
  for i:=Hearts to Spades do
    if Pos(s[1],SuitStrings[i])<>0 then begin
      StrToSuit:=i; Break;
    end;
end;
 
function StrToRank(s: string): TRank;
var i: TRank;
begin
  StrToRank:=ErrRank;
  if s='' then Exit;
  for i:=Ace to King do
    if Pos(s[1],RankStrings[i])<>0 then begin
      StrToRank:=i; Break;
    end;
end;
 
var
  Deck: TDeck;
  rank: TRank;
  suit: TSuit;
  s, c: string;
begin
  for suit:=Hearts to Spades do Deck[suit]:=[];
  Write('Допустимые обозначения рангов:');
  for rank:=Ace to King do Write(' ',RankStrings[rank]); WriteLn;
  Write('Допустимые обозначения мастей:');
  for suit:=Hearts to Spades do Write(' ',SuitStrings[suit]); WriteLn;
  WriteLn('Вводите через пробел последовательность карт в виде РангМасть,');
  WriteLn('для завершения ввода нажмите Enter:');
  repeat
    Write('> '); ReadLn(s);
    if s='' then Break;
    s:=s+' ';
    while Copy(s,1,1)=' ' do Delete(s,1,1);
    repeat
      c:=Copy(s,1,Pos(' ',s)-1);
      suit:=ErrSuit; rank:=StrToRank(s);
      if rank<>ErrRank then begin
        Delete(s,1,1+Integer(rank=Ten));
        suit:=StrToSuit(s);
      end;
      if (rank=ErrRank) or (suit=ErrSuit) then
        WriteLn('*** Не опознана карта: "', c, '"')
      else
        Include(Deck[suit],rank);
      Delete(s,1,Pos(' ',s));
      while Copy(s,1,1)=' ' do Delete(s,1,1);
    until s=''
  until false;
  Write('Содержимое колоды:');
  for suit:=Hearts to Spades do
    for rank:=Ace to King do
      if rank in Deck[suit] then
        Write(RankToStr(rank):3,SuitToStr(suit));
end.

 TRank = (ErrRank,
    Two, Three, Four, Five, Six, Seven, Eight, Nine, Ten,
    Jack, Queen, King, Ace);

uses crt;
const
  SuitColors: array [TSuit] of Byte = (Yellow, Red, Red, DarkGray, DarkGray);
...
  for suit:=Hearts to Spades do
    for rank:=Ace to King do
      if rank in Deck[suit] then begin
        TextColor(SuitColors[suit]);
        Write(RankToStr(rank):3,SuitToStr(suit));
      end;
  NormVideo;
end.

 Uses Crt; 
 type
   mast = (W,K,B,H);//перечислимый тип масти(вини,крести..)
   long = string[3];
     karts = (six,seven,eight,nine,ten,valet,dama,corol,tuz);
      kart = set of karts;  
    kol = array [mast] of kart; //в массиве 4 множества по числу мастей
 const    // для вывода на экран достоинства карты 
      kar : array [karts] of long = ('6','7','8','9','10','v','d','c','t');
  var  ko: kol; //ko переменная массива kol
        i: mast; // переменная перечислимого типа mast
        j: karts; // переменная перечислимого типа karts
        m: byte; // количество вводимых карт
function limit:byte;  // определяет количество вводимых карт 
 begin
writeln('введите кол-во карт кот.надо занести в колоду не более 36');
writeln('eсли введете 36,то массив карт заполнится автоматически');
 repeat
   readln(m);
 until(0 < m)and(m < 37);
   ClrScr; // очищаем экран от того строк и введенной цифры m
   limit:= m;
 end;
{ zap заполняем колоду в зависимости от количества 
 если m ввели = 36 ,то колода заполняется автоматом,
 если m ввели меньше 36 ,то вводим все вручную }
procedure zap(var ko: kol;const k:byte);
  begin
  if k = 36 then
    for i:= w to h do
     for j:= six to tuz do
       include(ko[i],j)
     { for i:= w to h do //или так - тоже вся колода
     for j:= six to tuz do
    ko[i]:= ko[i] + [j]; }
       else
  if k < 36 then  begin
writeln('введите масть W,K,B,H и через пробел достоинство карты(six,seven..) и нажмите  Enter');
    for m:= 1 to k do begin
      read(i,j);//i- W,K,B,H масть,j-карты перечисл.тип
      include(ko[i],j) //вставляем в массив множеств ко
    end;// для for m:= 1
      ClrScr; //очищаем экран от того что вводили здесь
  end; // для  if k < 36
  end; // конец процедуры zap
procedure output(ko: kol);
 begin
  for i:= w to h do begin
     for j:= six to tuz do
    if j in ko[i] then write ( i, kar [j], ' ');//выводим в строку все карты одной масти
      writeln; // переход на другую строку 
     end;
 end;
begin  ClrScr;
 zap(ko,limit);//limit кол-во карт кот.надо занести в колоду не более 36
 output(ko);
   readln; // прога ждет нажатия enter
end.