Стандартные операции с массивами (матрицами)

@Unrealler · Регистрация: 11.12.2009

Студворк — интернет-сервис помощи студентам

-------------------------------------------------------------------------------------------
Содержание:

-------------------------------------------------------------------------------------------

1) Очень часто на форуме просят "переворот" массива. Например, было

Code
1
1 2 3 4 5

Стало

Code
1
5 4 3 2 1

Осуществляется это так:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
var
   a:array[1..100] of integer;
   i,r,n:integer;
begin
 readln(n); {читаем размер массива}
 for i:=1 to n do
  read(a[i]);
 for i:=1 to n div 2 do   {сам "переворот"}
  begin
   r:=a[i];
   a[i]:=a[n-i+1];
   a[n-i+1]:=r;
  end;
 for i:=1 to n do
  write(a[i],' ');
 readln
end.

2) Не менее возникает вопрос о сдвиге массива на k элементов влево или вправо.
Было

Code
1
1 2 3 4 5

Стало

Code
1
5 1 2 3 4

Сдвиг влево на k элементов:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
var
   a:array[1..100] of integer;
   i,r,n,k,j:integer;
begin
 read(n,k);  {k обозначает величину сдвига}
 for i:=1 to n do
  read(a[i]);
 for i:=1 to k do
  begin
   for j:=1 to n do
    if (j=1) then r:=a[j] else a[j-1]:=a[j];
   a[n]:=r;
  end;
 for i:=1 to n do
  write(a[i],' ');
 readln
end.

Сдвиг на k элементов вправо:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
var
   a:array[1..100] of integer;
   i,r,n,k,j:integer;
begin
 read(n,k);  {k обозначает величину сдвига}
 for i:=1 to n do
  read(a[i]);
 for i:=1 to k do
  begin
   for j:=n downto 1 do
    if (j=n) then r:=a[n] else a[j+1]:=a[j];
   a[1]:=r;
  end;
 for i:=1 to n do
  write(a[i],' ');
 readln
end.

@Даня98 · 29.07.2011, 14:16

Заполнение массива по спирали
Очень часто это задание попадается для разминки.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
uses crt;
var a: array [1..100,1..100] of integer;
    i,m,k,n: integer;
begin
writeln ('Vvesti chislo');
readln (n);
k:=0;
m:=0;
repeat
for i:= m+1 to n-m do
begin
inc (k);                      
a[i,m+1]:= k;
end;
for i:= m+2 to n-m do
begin                             
inc (k);
a[n-m,i]:= k;
end;
for i:= n-m-1 downto m+1 do
begin
inc (k);                                  
a[i,n-m]:= k;
end;
for i:= n-m-1 downto m+2 do
begin
inc (k);
a[m+1,i]:=k;
end;
inc (m);
until m+1=n div 2 + 2;
for i:= 1 to n do
begin
for k:= 1 to n do
write (a[i,k]:3,' ');
writeln;
end;
end.

@Sagittarius · 14.01.2012, 19:19

Построение синусоиды на двумерном массиве(матрице) из точек(.)

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
program project1;
uses crt;
const w=79;{Ширина массива} h=22; {Высота массива}
var i,j,k: integer;
    arr: array [1..h,1..w] of char; 
begin
    ClrScr; {Очищаем экран}
        {Заполняем массив точками '.'}
    for j:=1 to h do
        for i:=1 to w do
        begin
            arr[j,i]:='.';
        end;
        {Запоняем некоторые элементы массива,
            которые выявляются по формуле, звездочками '*'} 
    for j:=1 to w do
    begin
         k:=round((sin(3.0*j*PI/w)+1)/2*h);
         arr[k,j]:='*';
    end;
        {Выводем массив}
  for j:=1 to h do
  begin
    writeln;
        for i:=1 to w do
            write(arr[j,i]);
   end;
 
   readln;
end.

Примерно так:

Стандартные операции с массивами (матрицами)

@Севак · 15.03.2012, 12:33

Думаю кому-нибудь будет полезно: вставление нового столбца в матрицу со сдвигом исходных элементов, например: вставить столбец между 5 и 6 столбцом исходной матрицы.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
uses crt;
var
a: array[1..10,1..12] of integer;
b: array[1..10] of integer;
i,k,n,j,q: integer;
 
begin
write('Введите размерность матрицы, не больше 10 и не меньше 6 : ');
repeat
read(n);
until (n>=6) and (n<11);
 
writeln('Введите элементы одномерного массива:');
for k:=1 to n do begin
read(b[k]);
end;
 
write('В какой столбец будут вставляться элементы: ');
repeat
read(q);
until (q>=1) and (q<=n);
 
writeln('Для вывода результата нажмите ENTER...');
readln;
clrscr;
 
write('Исходная матрица:');
writeln;
for i:=1 to n do begin
for j:=1 to n do begin
a[i,j]:=random(10);
write(a[i,j]:4);
end;
writeln;
end;
 
for j:=n+1 downto q do begin
for i:=1 to n do begin
a[i,j+1]:=a[i,j];
end;
end;
 
for i:=1 to n do begin
a[i,q]:=b[i];
end;
 
writeln;
writeln('Полученная матрица:');
for i:=1 to n do begin
for j:=1 to n+1 do begin
write(a[i,j]:4);
end;
writeln;
end;
end.

Добавлено через 9 минут
аналогично предыдущей программе, только вставление строки:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
uses crt;
var
a: array[1..12,1..10] of integer;
b: array[1..10] of integer;
i,k,n,j,q: integer;
 
begin
write('Введите размерность матрицы, не больше 10 и не меньше 6 : ');
repeat
read(n);
until (n>=6) and (n<11);
 
writeln('Введите элементы одномерного массива:');
for k:=1 to n do begin
read(b[k]);
end;
 
write('В какую строку будут вставляться элементы: ');
repeat
read(q);
until (q>=1) and (q<=n);
 
writeln('Для вывода результата нажмите ENTER...');
readln;
clrscr;
 
write('Исходная матрица:');
writeln;
for i:=1 to n do begin
for j:=1 to n do begin
a[i,j]:=random(10);
write(a[i,j]:4);
end;
writeln;
end;
 
for i:=n+1 downto q do begin
for j:=1 to n do begin
a[i+1,j]:=a[i,j];
end;
end;
 
for i:=1 to n do begin
a[q,i]:=b[i];
end;
 
writeln;
writeln('Полученная матрица:');
for i:=1 to n+1 do begin
for j:=1 to n do begin
write(a[i,j]:4);
end;
writeln;
end;
end.

@SeryZone · 09.04.2012, 19:54

А вот моя разработка переворота на 90^о по часовой стрелке!

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
var
  a: array[1..50, 1..50] of longint;
  i, j, n, m: integer;
 
begin
  readln(n, m); 
  if (n >= 1) and (m >= 1) and (n <= 50) and (m <= 50) then
  begin
    for i := 1 to n do
      for j := 1 to m do
        read(a[i, j]);
    writeln(m,' ',n);
    for i:=1 to m do
    begin
      for j := n downto 1 do
        if (j>1) then write(a[j,i], ' ') else write(a[j,i]);
      if (i<m) then writeln;
    end;
  end;
end.

@Erea · 25.04.2013, 00:08

Заполнение массива неповторяющимися значениями:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
program Myprogram;
type Tarr = array of integer;
 
procedure FillArray(var a:Tarr; n, r1, r2: integer);{a - массив;
                                                     n - длина массива;
                                                     r1, r2 - диапазоны рандома}
var i, j: integer;
    p: boolean;
begin
randomize;
setlength(a,n);
if r2-r1<n then begin
for i:=1 to n-1 do a[i]:=random(r2-r1+1)+r1;
end else begin
a[0]:=random(r2-r1+1)+r1;
p:=false;
for i:=1 to n-1 do begin
    repeat
    a[i]:=random(r2-r1+1)+r1;
    p:=false;
    for j:=0 to i-1 do begin
    if a[j]=a[i] then p:=true;
    end;
    until p=false;
end;
end;
end;
 
procedure WriteArray(a: Tarr);
var i: integer;
begin
for i:=0 to length(a)-1 do begin
write(a[i]:4);
end;
writeln;
end;
 
var MyArray: Tarr;
begin
FillArray(MyArray, 10, 0, 10);
WriteArray(MyArray);
readln;
end.

@APALoff · 23.10.2014, 15:48

16)

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
Const n=5;
Var
  m   : array[1..n,1..n] of Integer;
  i,j : Byte;
Begin
  For i:=1 to n do
   For j:=1 to n do m[i,Ord(not Odd(i))*(n+1-j)+Ord(Odd(i))*j]:=(i-1)*n+j;
  
  For i:=1 to n do
  Begin
    For j:=1 to n do Write(m[i,j]:4);
    Writeln;
  end;
end.

@Puporev · 23.10.2014, 15:57

В простом АВС это не рулит, а количество циклов нужно сократить.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Const n=5;
Var
  m   : array[1..n,1..n] of Integer;
  i,j : Byte;
Begin
For i:=1 to n do
 begin
  For j:=1 to n do
   begin
    m[i,Ord(not Odd(i))*(n+1-j)+Ord(Odd(i))*j]:=(i-1)*n+j;
    Write(m[i,j]:4);
   end;
  Writeln;
 end;
end.

@volvo · 23.10.2014, 16:04

Сообщение от Puporev

количество циклов нужно сократить

Только не в ущерб правильности ответа. Приведенный в посте №27 код работает некорректно:

Code
1
2
3
4
5
   1   2   3   4   5
   0   0   8   7   6
  11  12  13  14  15
   0   0  18  17  16
  21  22  23  24  25

@Puporev · 23.10.2014, 16:07

Согласен, лажанулся...

@roma070201 · 06.12.2014, 22:31

Сообщение от Unrealler

if (j=n) then r:=a[n] else a[j+1]:=a[j];

можно ли написать без if'а , а как-нибудь по другому?

@JokeR.BY · 07.12.2014, 04:56

roma070201, как вы себе это представляете? тут же совершенно разные переменные.

@Mawrat · 07.12.2014, 12:28

Сообщение от roma070201

можно ли написать без if'а , а как-нибудь по другому?

С учётом окружающего кода - можно. Имеем:

Pascal
1
2
3
4
5
6
for i:=1 to k do
begin
  for j:=n downto 1 do
    if (j=n) then r:=a[n] else a[j+1]:=a[j];
  a[1]:=r;
end;

Тогда без IF будет так:

Pascal
1
2
3
4
5
6
7
for i:=1 to k do
begin
  r := a[n]; 
  for j:= n - 1 downto 1 do
    a[j+1]:=a[j];
  a[1]:=r;
end;

@bormant · 15.01.2017, 15:31

Сдвиг массива на k элементов за линейное время

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
{ сдвиг массива a на n элементов (вправо для n>0, влево для n<0 }
procedure rotate(var a: array of Integer; n: Integer);
  procedure rev(b, e: Integer);
  var t: Integer;
  begin
    while b<e do begin
      t:=a[b]; a[b]:=a[e]; a[e]:=t;
      Inc(b); Dec(e);
    end;
  end;
begin
  n:=n mod (High(a)+1); if n=0 then Exit;
  if n<0 then Inc(n,High(a)+1);
  rev(Low(a),High(a)); rev(0,n-1); rev(n,High(a));
end;

@bormant · 24.10.2017, 19:46

А вот еще более эффективный сдвиг (за один проход):

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
procedure vRotate(var a: array of Integer; shift: Integer); {+ влево, - вправо}
var b, c, t, size: Integer;
begin
  size:=High(a)+1;
  shift:=shift mod size; if shift<0 then Inc(shift,size);
  if shift=0 then Exit;
  b:=0;
  while (b<>shift) and (shift<>size) do begin
    c:=shift;
    while (b<>shift) and (c<>size) do begin
      t:=a[b]; a[b]:=a[c]; a[c]:=t;
      Inc(b); Inc(c);
    end;
    if b=shift then shift:=c;
  end;
end;

@bormant · 08.02.2018, 16:00

И еще циклический сдвиг за один проход фрагмента массива [fst,lst) так, что mid становится на место fst:

Pascal
1
2
3
4
5
6
7
8
9
10
11
procedure vRotate(var a: array of Integer; fst, mid, lst: Integer);
var nxt: Integer; t: Integer;
begin
  nxt:=mid;
  while fst<>nxt do begin
    t:=a[fst]; a[fst]:=a[nxt]; a[fst]:=t;
    Inc(fst); Inc(nxt);
    if      nxt=lst then nxt:=mid
    else if fst=mid then mid:=nxt;
  end;
end;

то же самое на указателях (предполагается, что эти указатели образованы из элементов одного массива!!!):

Pascal
1
2
3
4
5
6
7
8
9
10
11
procedure vRotate(fst, mid, lst: PInteger);
var nxt: PInteger; t: Integer;
begin
  nxt:=mid;
  while fst<>nxt do begin
    t:=fst^; fst^:=nxt^; fst^:=t;
    Inc(fst); Inc(nxt);
    if      nxt=lst then nxt:=mid
    else if fst=mid then mid:=nxt;
  end;
end;

@bormant · 07.04.2018, 12:37

И еще один однопроходный вариант вращения [fst,fst+cnt) на shift элементов (<0 -- влево, >0 -- вправо).
по мотивам https://www.cyberforum.ru/post4788988.html

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
procedure vRotate(var a: array of Integer; fst, cnt, shift: Integer);
var t: Integer;
begin
  if cnt < 2 then Exit;
  shift:=shift mod cnt; if shift = 0 then Exit;
  if       shift > cnt shr 1 then Dec(shift,cnt)
  else if -shift > cnt shr 1 then Inc(shift,cnt);
  if shift > 0 then
    for fst:=fst-shift+cnt-1 downto fst do begin
      t:=a[fst+shift]; a[fst+shift]:=a[fst]; a[fst]:=t;
    end
  else
    for fst:=fst-shift to fst+cnt-1 do begin
      t:=a[fst+shift]; a[fst+shift]:=a[fst]; a[fst]:=t;
    end;
end;

@Вадим Мошев · 14.09.2018, 15:48

Преобразование двумерного массива (матрицы) в одномерный.
Задача простая, но её решение часто спрашивается. Публикую только "решающую часть", то есть, саму обработку. Объявление переменных, инициализацию, ввод данных и их вывод я опустил.

Pascal
1
2
3
4
5
6
7
8
9
10
11
{Предположим, что двумерный массив с его размерность уже задана}
 
arrayElementsNumber:=0;
for i:=1 to rowsNumber do begin
    for j:=1 to columnsNumber do begin
        inc(arrayElementsNumber);
        a[arrayElementsNumber]:=matrix[i, j];
    end;
end;
 
{На выходе имеем одномерный массив, хранящийся в переменной a. Размерность этого массива равна arrayElementsNumber}

Новые блоги и статьи Все статьи Все блоги /
Когда логика программы не спасает от человеческих ошибок Maks 18.08.2026 В последнее время всё чаще и чаще сталкиваюсь с таким явлением, как абсолютная невнимательность (или глупость) пользователей. Проявляется это чаще всего на работе в коллективе. Допустим, человек с. . .	Лето уходит kumehtar 17.08.2026	Мысли в слух kumehtar 17.08.2026 Забавно, насколько сейчас стала доступна информация. Например о магии, духовном развитии, медитациях, и других подобных направлениях, ранее зачастую тайных, передаваемых от учителя к ученику. Хотя. . .	Перемещение строк из ТЧ в другой документ с учетом текущего пробега Maks 17.08.2026 Реализация из решения ниже выполнена на примере нетипового документа "Автозапчасти", с ТЧ "Шины". За основу взят алгоритм отсюда: https:/ / www. cyberforum. ru/ blogs/ 359708/ 10838. html Задача: . . .
Саморегулирующийся социальный контракт для сервера cross-section. Hrethgir 14.08.2026 С кодом конечно таких глубоких размышлений пока не было, впрочем я уже привык к алгоритмизации. Суть предмета записи: снова в диалоге с нейросетью (я взял пока себе ник для учётки админа - Rector). . . .	Часы электронные Uhbif79 12.08.2026 Выкладываю программу часов. Программа позволяет: 1. Использовать системное время и дату, 2. Есть возможность вводить время и дату вручную. 3. Реализованы 2 будильника: начало и конец рабочего дня. . . .	Часы с будильником на основе класса QLCDNumber Uhbif79 12.08.2026 Всем добрый день, выкладываю программу часов с будильником на основе класса QLCDNumber. Здесь я пробовал самостоятельно создавал классы, впервые столкнулся с видимостью переменной одного класса из. . .	Установка MinGW GCC 16.2 и CMake 8Observer8 10.08.2026 VK Видео: https:/ / vkvideo. ru/ video-240781534_456239017 YouTube: eY5-5PyI9NM Текстовая версия

Стандартные операции с массивами (матрицами)

Решение

Решение

@Puporev Почетный модератор 64320 / 47616 / 32743 Регистрация: 18.05.2008 Сообщений: 115,167
	23.10.2014, 16:07
	Согласен, лажанулся... 0

@JokeR.BY CAPITAL OF ROCK! 1281 / 708 / 982 Регистрация: 03.03.2010 Сообщений: 2,286
	07.12.2014, 04:56
	roma070201, как вы себе это представляете? тут же совершенно разные переменные. 0