Динамические структуры данных: списки

type
    PItem = ^TItem;
    TItem = record  {элемент списка}
        Data:Integer;  {данные элемента}
        Next:PItem;  {указатель на следующий элемент}
    end;
 
procedure NewList(var L:PItem; Len:Integer);
{создаем новый список в переменной L}
var p:PItem; i:Integer;
begin
    if Len<=0 then begin  {если длина равна 0}
        L := nil;  {то список пустой}
        exit;
    end;
    i := 1;
    new(L);  {создаем новый элемент списка}
    L^.Data := i;
    inc(i);
    p := L;  {копируем указатель на элемент}
    dec(Len);
    while Len>0 do begin {пока длина не закончилась}
        new(p^.Next); {создаем следующий элемент списка}
        p := p^.Next; {и переходим на него}
        p^.Data := i;
        inc(i);
        dec(Len); {убавляем длину}
    end;
    p^.Next := nil; {у последнего элемента списка нет следующего}
end;
 
procedure DisposeList(var L:PItem);
{уничтожаем список, освобождаем память}
var p:PItem;
begin
    while L<>nil do begin {пока список не пуст}
        p := L;  {текущий элемент списка}
        L := L^.Next; {список теперь начинается со следующего элемента}
        dispose(p); {а текущий удаляем}
    end;
end;
 
procedure PrintList(L:PItem);
{выводим данные из списка}
var b:boolean;
begin
    write('(');
    b := false; {вспомогательна переменная для запрета лишней запятой в начале}
    while L<>nil do begin {пока в списке еще есть элементы}
        if b then write(', ') else b := true;
        write(L^.Data); {выводим текущий элемент}
        L := L^.Next; {и переходим на следующий}
    end;
    writeln(')');
end;
 
var list:PItem;
begin
    NewList(list, 10); {создаем список}
    write('list = ');
    PrintList(list); {выводим список}
    DisposeList(list); {уничтожаем список}
end.

uses crt;
 
type
 Pelo= ^Telo;
 Telo = record
        head: integer;
        tail: Pelo;
 end;
 
 
procedure Add(var p: Pelo; el: integer);
var
 temp: Pelo;
begin
 temp := new(Pelo);
 temp^.head := el;
 temp^.tail := p;
 p := temp;
end;
 
procedure PrintPelo(p: Pelo);
begin
 write(p^.head, ' ');
 if p^.tail<>nil then
   PrintPelo(p^.tail);
end;
 
var
 t1: Pelo;
 k, i: integer;
begin
 clrscr;
 t1 := new(Pelo);
 t1^.head  := 17;
 t1^.tail := nil;
 for i:=1 to 15 do
   begin
    k := random(15)+1;
    Add(t1, k);
    write(k, ' ');
   end;
 writeln;
 PrintPelo(t1);
 readln;
end.

procedure Add(var p: Pelo; el: integer);
var
 temp: Pelo;
begin
 temp := new(Pelo);
 temp^.head := el;
 temp^.tail := p^.tail; {новый указывает на бывший второй}
 p^.tail := temp; {а первый указывает на новый}
end;