Построить интерполяционный многочлен Лагранжа

function f(x: real): real; //Ваша функция
begin
  f := exp(cos(x) * ln(4))
end;
 
const
  m = 5; //максимальный номер узла
type
  arr = array[0..m] of real; //тип для массива узлов и массива для интерполяции
const
  xp: arr = (0.6, 0.8, 0.9, 1.0, 1.3, 1.4); //узловые точки
  a = 0.5; //начало интервала
  h = 0.02; //шаг
  b = 1.5 + h / 2; //конец интервала и компенсация ошибок усечения
var
  fp: arr; //массив для интерполяции
  x, y, L: real; //аргумент, значение функции, значение многочлена
  i, j: integer; //счётчики
begin
  x := a; //начальное значение аргумента
  writeln('  x        L(x)            f(x)         L(x)-f(x)');
  while x <= b do //цикл табуляции функции и многочлена
    begin
      y := f(x); //значение функции
      L := 0; //начальное значение многочлена
      for i := 0 to m do //цикл интерполяции
        begin
          fp[i] := f(xp[i]); //значение функции в очередной узловой точке
          for j := 0 to m do //цикл вычисления значения очередного базисного полинома
            if i <> j then fp[i] := fp[i] * (x - xp[j]) / (xp[i] - xp[j]);
          L := L + fp[i] //добавление очередного базисного полинома к многочлену
        end;
      writeln(x:4:2, L:16:12, y:16:12, L-y:16:12); //печать результата
      x := x + h //следующий аргумент
    end;
  readln //ожидание нажатия <Enter> перед закрытием программы
end.