Кольцевой двунаправленный список: удалить все элементы, у которых одинаковые соседи

var
    a,b,n:string;
         i,j,c:integer;
begin
    readln(n);
     for i:=1 to length(n)-2 do
      for j:=i+2 to length(n) do
       if (n[i]=n[j]) then delete(n,j-1,1);
    write(n);
    end.

program Project1;
 
type
  //Тип основных данных списка.
  TData = Integer;
  //Указатель на элемент списка.
  TPElem = ^TElem;
  //Элемент списка.
  TElem = record
    Data : TData; //Основные данные.
    FDel : Boolean; //True - элемент должен быть удалён. Иначе - False.
    PNext, PPrev : TPElem; //Указатели на следующий и на предыдущий элеметы списка.
  end;
  //Список.
  TDList = record
    Cnt : Integer;   //Количество элементов в списке.
    PFirst : TPElem; //Указатель на первый элемент списка.
  end;
 
//Процедуры для работы с двунаправленным кольцевым списоком.
 
//Процедура начальной инициализации. Внимание! Эту процедуру можно выполнять
//только в отношении пустого списка. Иначе, будут утечки памяти.
procedure Init(var aList : TDList);
begin
  aList.Cnt := 0;
  aList.PFirst := nil;
end;
 
//Удаление двунаправленного кольцевого списка из памяти и инициализация.
procedure Free(var aList : TDList);
var
  PElem, PDel : TPElem;
begin
  if aList.PFirst = nil then Exit;
 
  PElem := aList.PFirst;
  repeat
    PDel := PElem;
    PElem := PElem^.PNext;
    Dispose(PDel);
  until PElem = aList.PFirst;
  Init(aList);
end;
 
//Добавление элемента в конец двунаправленного кольцевого списка.
//Если список пуст, то новый элемент становится первым элементом списка.
//Если список не пуст, то новый элемент добавляется перед первым элементом списка.
procedure Add(var aList : TDList; const aData : TData);
var
  PElem : TPElem;
begin
  New(PElem);
  PElem^.Data := aData;
  PElem^.FDel := False;
  if aList.PFirst = nil then begin //Если список пуст.
    aList.PFirst := PElem;
    PElem^.PNext := PElem; //Указатель на самого себя.
    PElem^.PPrev := PElem; //Указатель на самого себя.
  end else begin //Если список не пуст.
    PElem^.PNext := aList.PFirst;
    PElem^.PPrev := aList.PFirst^.PPrev;
    PElem^.PPrev^.PNext := PElem;
    PElem^.PNext^.PPrev := PElem;
  end;
  Inc(aList.Cnt);
end;
 
//Распечатка двунаправленного кольцевого списка.
procedure Print(const aList : TDList);
var
  PElem : TPElem;
begin
  if aList.PFirst = nil then Exit;
 
  PElem := aList.PFirst;
  repeat
    if PElem <> aList.PFirst then Write(', ');
    Write(PElem^.Data);
    PElem := PElem^.PNext;
  until PElem = aList.PFirst;
end;
 
//Удаление элемента из списка.
procedure Del(var aList : TDList; const aPElem : TPElem);
begin
  if (aList.PFirst = nil) or (aPElem = nil) then Exit;
 
  //Если элемент указывает сам на себя, то он единственный элемент в списке.
  if aPElem = aPElem.PNext then
    aList.PFirst := nil
  //Если в списке два и более элементов.
  else begin
    aPElem^.PPrev^.PNext := aPElem^.PNext;
    aPElem^.PNext^.PPrev := aPElem^.PPrev;
    if aList.PFirst = aPElem then aList.PFirst := aPElem^.PNext;
  end;
  Dispose(aPElem); //Освобождение памяти, занятой элементом.
  Dec(aList.Cnt);
end;
 
//Удаление из двунаправленного кольцевого списка элементов, которые имеют
//соседей с одинаковыми значениями.
//Функция возвращает количество удалённых элементов.
function Proc(var aList : TDList) : Integer;
var
  PElem, PDel : TPElem;
  Cnt : Integer;
begin
  Proc := 0;
  if aList.PFirst = nil then Exit;
 
  //Помечаем элементы, которые надо удалить.
  PElem := aList.PFirst;
  repeat
    if
      (PElem^.PNext <> PElem)
      and (PElem^.PPrev^.Data = PElem^.PNext^.Data)
    then
      PElem^.FDel := True;
    PElem := PElem^.PNext;
  until PElem = aList.PFirst;
 
  //Удаление помеченных элементов.
  Cnt := 0;
  PElem := aList.PFirst;
  repeat
    PDel := nil;
    if PElem^.FDel then begin
      PDel := PElem;
      PElem := PElem^.PNext;
      Del(aList, PDel);
      Inc(Cnt);
    end else
      PElem := PElem^.PNext;
  until (aList.PFirst = nil) or ( (PElem = aList.PFirst) and (PDel = nil) );
  //Пояснение.
  //Цикл надо завршить если:
  //(aList.PFirst = nil) - список пуст (т. е., оказались удалены все элементы);
  //или
  //( (PElem = aList.PFirst) and (PDel = nil) ) - текущий элемент является
  //первым в списке и при этом не было произведено удаление.
 
  Proc := Cnt;
end;
 
//Диалог для добавления элементов в конец списка.
procedure WorkAdd(var aList : TDList);
var
  S : String;
  Data : TData;
  Code : Integer;
begin           
  Writeln('Добавление элементов в список.');
  Writeln('Ввод каждого значения завершайте нажатием Enter.');
  Writeln('Чтобы прекратить ввод оставьте пустую строку и нажмите Enter.');
  repeat
    Write('Элемент №', aList.Cnt + 1, ': ');
    Readln(S);
    if S = '' then begin
      Writeln('Отмена.');
      Code := 0;
    end else begin
      Val(S, Data, Code);
      if Code = 0 then begin
        Add(aList, Data);
        Writeln('Элемент добавлен.');
        Code := 1;
      end else
        Writeln('Неверный ввод. Повторите.');
    end;
  until Code = 0;
  Writeln('Ввод элементов списка завершён.');
end;
 
var
  L : TDList;
  Cmd, Cnt : Integer;
begin
  //Начальная инициализация списка.
  Init(L);
 
  repeat
    //Меню
    Writeln('Выберите действие:');
    Writeln('1: Добавление элементов в список.');
    Writeln('2: Распечатка списка.');
    Writeln('3: Удаление элементов, у которых одинаковые значения соседей.');
    Writeln('4: Удаление списка.');
    Writeln('5: Выход.');
    Write('Введите команду: ');
    Readln(Cmd);
    case Cmd of
      1: WorkAdd(L);
      2:
        if L.PFirst = nil then
          Writeln('Спиосок пуст.')
        else begin
          Writeln('Содержимое списка:');
          Print(L);
          Writeln;
        end;
      3:
      begin
        Cnt := Proc(L);
        Writeln('Список обработан. Количество удалённых элементов: ', Cnt);
      end;
      4, 5:
      begin
        Free(L);
        Writeln('Список удалён из памяти (очищен).');
      end;
      else
        Writeln('Незарегистрированная команда. Повторите ввод.');
    end;
  until Cmd = 5;
 
  Writeln('Работа программы завершена. Для выхода нажмите Enter.');
  Readln;
end.