Построение графика функции

uses
  graphABC;
 
const
  w = 50;  
 
var
  a, b, mx, my, dx, n, dy, fmin, fmax: real;
  Q, x0, y0, i, j, x1, y: integer;
  s: string;
 
function F(x: real): real;
begin
  f := x*x*x-0.2*x*x-0.2*x-1.2;
end;
 
procedure Interval(d: real; var a, b: real);
begin
  if frac(a / d) <> 0 then a := d * trunc(a / d) - d;
  if frac(b / d) <> 0 then b := d * trunc(b / d) + d;
end;
 
///Процедура вычисляет начало координат x0, y0
procedure NachaloCoordinat(a, b, fMin, fMax, mx, my: real);
begin
  if a < 0 then
    if b < 0 then x0 := WindowWidth - w
    else x0 := trunc(abs(a) * mx) + w
  else x0 := w;
  if fMin < 0 then
    if fMax < 0 then y0 := w + 0
    else y0 := WindowHeight - trunc(abs(fMin) * my) - w
  else y0 := WindowHeight - w;
end;
 
///Процедура рисования графика f(x)
procedure Graphik();
var
  x1, y1: real;
  i, x, y: integer;
  bln: boolean;
begin
  { Строим график с помощью маленьких отрезков: }
  bln := false;
  Q := WindowWidth - 2 * w;
  for i := 0 to Q do 
  begin
    x1 := a + i / mx;
    y1 := f(x1);
    if abs(y1) < maxReal then y := y0 - round(y1 * my);
    if (a > 0) and (b > 0) then x1 := x1 - a
    else
    if (a < 0) and (b < 0) then x1 := x1 - b;
    x := x0 + round(x1 * mx);
    if bln then begin
      if (y in [w..windowheight - w]) then LineTo(x, y)
      else bln := false
    end
    else
      if (y in [w..windowheight - w]) then begin
        MoveTo(x, y);
        bln := true
      end
  end
end;
 
begin
  SetWindowSize(800, 600);
  a := 1; b := 1.5; dx := 0.02;
  fmin := -1; fmax := 1.6; dy := 0.2;
  Interval(dx, a, b);
  Interval(dy, fmin, fmax);
  mx := (windowwidth - 2 * w) / (b - a); //масштаб по Х
  my := (windowheight - 2 * w) / (fmax - fmin); //масштаб по Y
  NachaloCoordinat(a, b, fMin, fMax, mx, my);
  Line(10, y0, WindowWidth - 10, y0);  //OX
  Line(x0, 10, x0, WindowHeight - 10); //OY
  SetFontColor(clRed);
  TextOut(WindowWidth - 20, y0 + 10, 'X');
  TextOut(x0 + 5, 10, 'Y');
  SetFontSize(8);
  SetFontColor(clBlue);
  { Засечки на оси OX: }
  j := round((b - a) / dx) + 1; //j - количество засечек
  for i := 1 to j do 
  begin
    x1 := w + trunc((i - 1) * Mx * dx);
    Line(x1, y0 - 3, x1, y0 + 3); //рисуем засечки на оси OX
    n := a + (i - 1) * dx;
    Str(n, s);
    if abs(n) > 0.00001 then TextOut(x1 - TextWidth(s) div 2, y0 + 10, FloatToStr(n)); 
    { Вертикальная сетка: }
    SetPenColor(RGB(200, 200, 200));
    SetpenStyle(psDot);
    if abs(N) > 0.00001 then begin
      Line(x1, w, x1, y0 - 15);
      Line(x1, y0 + 30, x1, WindowHeight - w)
    end;
  end;
  { Засечки на оси OY: }
  j := round((fmax - fmin) / dy) + 1; //j - количество засечек
  for i := 1 to j do 
  begin
    y := windowheight - w - trunc((i - 1) * My * dy);
    Line(x0 - 3, y, x0 + 3, y); //рисуем засечки на оси Oy
    n := fmin + (i - 1) * dy;
    if abs(N) > 0.00001 then TextOut(x0 + 7, y - 8, FloatToStr(n));
    { Горизональная сетка: }
    SetPenColor(RGB(200, 200, 200));
    SetpenStyle(psDot);
    if abs(N) > 0.000001 then begin
      Line(w, y, x0 - 10, y); 
      Line(x0 + 20, y, WindowWidth - w, y)
    end;
  end;
  SetPenColor(clGreen);
  SetPenWidth(2);
  SetpenStyle(psSolid);
  Graphik()
end.