С Pascal в С++ перевести задачку - C++ - Ответ 2440331

program zadanie_5;
uses crt;
const nn=15;
var n, i, j, k, imax, jmax: integer;
    a: array [1..nn,1..nn] of real;
    b:array[1..nn] of real;{массив для запоминания строк и столбцов}
    r: real;
    f:boolean;
begin
 randomize;
 repeat
 write('Задайте размер матрицы до ',nn,' n=');
 readln(n);
 until n in [1..nn];
 writeln('Исходный массив:');
 for i:=1 to n do
  begin
   for j:=1 to n do
    begin
     a[i,j]:=10*random;
     write(a[i,j]:5:2);
    end;
   writeln;
  end;
 for i:=1 to n-1 do {количество подмассивов, последний из 1 элемента не трогаем}
  begin
   imax:=i;  {считаем левый верхний элемент подмассива кандидатом на максимум}
   jmax:=1;
   for k:=i to n do  {цикл для перебора подмассивов}
   for j:=1 to n-i+1 do
   if a[k,j]>a[imax,jmax] then {для поиска максимального элемента}
    begin
     imax:=k;{нашли - делаем этот элемент максимальным}
     jmax:=j;
    end;
   if imax>i then{если максимальный не в первой строке подмассива}
    begin {сдвигаем (не обмениваем!) строки}
     for j:=1 to n do
     b[j]:=a[imax,j];  {запомним строку с максимумом}
     for k:=imax downto i+1 do {сдвинем строки вниз до макс.}
     for j:=1 to n do
     a[k,j]:=a[k-1,j];
     for j:=1 to n do {на место первой пишем строку с максимумом}
     a[i,j]:=b[j];
    end;
   if jmax<n-i+1 then{если максимальный не в последнем столбце подмассива}
    begin {сдвигаем столбцы}
     for k:=1 to n do
     b[k]:=a[k,jmax];{запомним столбец с макс.}
     for j:=jmax to n-i do{сдвинем столбцы влево до макс}
     for k:=1 to n do
     a[k,j]:=a[k,j+1];
     for k:=1 to n do {на место последнего пишем столбец с макс}
     a[k,n-i+1]:=b[k];
    end;
  end;
 writeln('Массив после перестановок:');
 for i:=1 to n do                     {вывод результата}
  begin
   for j:=1 to n do
   write (a[i,j]:5:2);
   writeln;
  end;
 {делаем проверку}
 f:=true;
 i:=2;
 while(i<=n)and f do
 if a[i,n-i+1]>a[i-1,n-i+2] then f:=false
 else i:=i+1;
 if f then write('На побочной диагонали убывающая последовательность')
 else write('Убывающая последовательность не получилась, ошибка в программе');
end.