Найти сумму элементов столбца матрицы, содержащего максимальный по модулю элемент - Assembler - Ответ 8842822

org 100h
jmp  start
 
hello   db  13,10,' CREATE ARRAY'         ; мессаги всякие
        db  13,10,25 dup('~'),13,10,'$'   ;
result  db  13,10,25 dup('~')             ;
        db  13,10,' MAX ELEMENT: $'       ;
summ    db  13,10,' COLUMN SUMM: $'       ;
array   db  12 dup(0)           ; место под массив (3х4)
max     db  1,0                 ; переменная для максимального (с позицией в массиве)
flag    db  0                   ; флаг отрицательного числа
 
start:
   mov   ah,9                 ;
   mov   dx,hello             ;
   int   21h                  ;
;=============================; ЗАПОЛНЯЕМ МАССИВ ============================
   mov   cx,12                ; всего 12 элементов (счётчик цикла)
   xor   bx,bx                ; BX = 0 (будет счётчиком столбцов)
   mov   di,array             ; адрес начала массива (для STOSB)
cycle:                        ;
   mov   al,' '               ;
   int   29h                  ; вставляем пробел/разделитель
   call  ASC2HEX              ; функция ввода числа с клавиатуры
   cmp   al,[max]             ; число больше переменной?
   jb    minimal              ; нет - пропускаем его
   mov   [max],al             ; иначе: отправляем его в переменную,
   mov   [max+1],cl           ; ..с сохранением позиции элемента в массиве
minimal:                      ;
   cmp   [flag],0             ; проверка флага на отрицательное число
   jz    miss                 ; если он сброшен - число положительное
   neg   al                   ; иначе: переводим число в NEGATE.
miss:                         ;
   stosb                      ; записываем это число в массив
   inc   bx                   ; счётчик столбцов +1
   cmp   bx,3                 ; это 4-ый столбец?
   jnz   next                 ; нет - продолжаем ввод чисел
   xor   bx,bx                ; да  - сбрасываем счётчик столбцов,
   mov   al,10                ; ...и перевод строки
   int   29h                  ;
next:                         ;
   mov   [flag],0             ; сбрасываем флаг для сл.числа
   loop  cycle                ; мотаем цикл СХ-раз..
                              ;
;=============================; ВЫВОДИМ НА ЭКРАН МАКС.ПО-МОДУЛЮ =============
   mov   ah,9                 ;
   mov   dx,result            ;
   int   21h                  ;
   mov   al,[max]             ; берём число в AL
   aam                        ; переводим его в распакованый DEC
   add   ax,3030h             ;     ..и в символьное представление
   xchg  ah,al                ;
   int   29h                  ;
   xchg  ah,al                ;
   int   29h                  ; выводим 2-значное число на экран!
                              ;
;=============================; ВЫЧИСЛЯЕМ НОМЕР СТОЛБЦА =====================
   mov   cx,12                ; сначала расчитываем позицию макс.эл в массиве
   sub   cl,[max+1]           ; позиция в CX!
   mov   ax,cx                ; ...она будет делимым
   mov   bx,3                 ; делитель (кол-во столбцов в массиве)
   xor   dx,dx                ; очищаем место под остаток
   div   bx                   ; DX = номер столбца!
                              ;
;=============================; НАХОДИМ СМЕЩЕНИЕ ПЕРВОГО ЭЛЕМЕНТА ===========
   mov   si,array             ; адрес начала массива (для LODSB)
   add   si,dx                ; SI = cмещение первого элемента в столбце!
                              ;
;=============================; СУММИРУЕМ ВСЕ ЭЛЕМЕНТЫ СТОЛБЦА ==============
   xor   ax,ax                ; сюда будем брать очередной элемент массива
   xor   bx,bx                ; здесь будет сумма
   mov   cx,4                 ; сколько элементов читать
adding:                       ;
   lodsb                      ; берём в AL байт из SI
   cbw                        ; расширяем байт до слова (byte2word)
   add   bx,ax                ; считаем сумму в ВХ
   add   si,2                 ; пропускаем 3 элемента (один пропустил LODSB)
   loop  adding               ; циклимся СХ-раз..
   push  bx                   ; запоминаем сумму в стеке!
                              ;
;=============================; ВЫВОДИМ СУММУ НА ЭКРАН ======================
   mov   ah,9                 ;
   mov   dx,summ              ;
   int   21h                  ;
   pop   ax                   ; снимаем сумму со-стека
   or    ax,ax                ; проверка суммы на отрицательное
   jns   ok                   ; если SF сброшен, то число положительное
   neg   ax                   ; иначе: перевод в положительное
   push  ax                   ;
   mov   al,'-'               ; выводим минус
   int   29h                  ;
   pop   ax                   ;
ok:                           ;
   call  HEX2ASC              ; и зовём функцию перевода чисел в символы!
                              ;
;=============================; ВЫХОД =======================================
exit:                         ;
   xor   ax,ax                ;
   int   16h                  ;
   int   20h                  ;
 
;нннннннннннннн ИСПОЛЬЗУЕМЫЕ ФУНКЦИИ нннннннннннннннннннннннннннннннннннннннн
;нннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннн
ASC2HEX:                      ; Функция ввода чисел с клавиатуры
                              ; На выходе: AX = число
   push  cx bx si             ; эти регистры изменятся. сохраняем их
   xor   si,si                ; здесь будет число
   mov   bx,10                ; система счисления для сохранения
   mov   cx,2                 ; число будет 2-значное (макс.99)
typeDigit:                    ;
   xor   ax,ax                ; ждём символ с клавиатуры..
   int   16h                  ;
   cmp   al,'-'               ; это минус?
   jne   positive             ; нет - пропускаем его
   int   29h                  ; да  - выводим минус на экран,
   int   16h                  ;    ..и ждём сл.символ
   inc   [flag]               ;
positive:                     ;
   cmp   al,'0'               ; если это не числа 0..9,
   jb    typeDigit            ; ^
   cmp   al,'9'               ; ^
   ja    typeDigit            ; то циклимся.
   int   29h                  ; наш клиент! выводим его на экран
   and   ax,0Fh               ; переводим символ в число,
   xchg  ax,si                ;
   mul   bx                   ;
   add   si,ax                ; ..и копим его в SI
   loop  typeDigit            ;
   xchg  ax,si                ; AX = двузначное число по-модулю
   pop   si bx cx             ; восстанавливаем регистры
RET                           ; возвращаемся туда, от куда прибыли..
 
;нннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннн
HEX2ASC:                      ; Функция переводит числа в символы
   pusha                      ; Вход:  АХ = число, BX = система счисления
   xor   cx,cx                ; счётчик разрядов числа
   mov   bx,10                ; система счисления (делитель)
isDiv:                        ;
   xor   dx,dx                ;
   div   bx                   ;
   push  dx                   ; остаток будет числом
   inc   cx                   ;
   or    ax,ax                ;
   jnz   isDiv                ;
isOut:                        ;
   pop   ax                   ; выводим его на экран
   add   al,30h               ;
   int   29h                  ;
   loop  isOut                ;
   popa                       ;
RET                           ; снимаем со-стека адрес возврата