Открыто ли окно?

@winkot · Регистрация: 26.10.2024

Студворк — интернет-сервис помощи студентам

Как определить открыто ли окно? Например, Блокнот?
Я так понимаю, что надо использовать Result = IsWindow(#Window). Но что подставить в качестве #Window?

@locm · 26.10.2024, 15:24

Нужно перечислить все окна других приложений и найти нужное окно по заголовку (должно быть слово Блокнот) или по имени процесса (notepad.exe).

PureBasic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Procedure EnumProcedure(hWnd, *Parameter.Integer)
  Protected Title.s{1024}, Res = #True
 
  If GetWindowText_(hWnd, @Title, 1024) > 0
    If FindString(LCase(Title), "блокнот")
      Res = #False
      *Parameter\i = #True
    EndIf
  EndIf
  ProcedureReturn Res
EndProcedure 
 
IsNotepad = #False
EnumWindows_(@EnumProcedure(), @IsNotepad)
 
If IsNotepad
  Debug "Окно блокнота найдено"
Else
  Debug "Окно блокнота не найдено"
EndIf

PureBasic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
Structure ProcInfo
  Name.s
  PID.l
EndStructure
 
Global NewList ProcList.ProcInfo()
 
Procedure ProcessList() ; Список процессов.
  Protected pe32.PROCESSENTRY32
  Protected hthSnapshot
  
  pe32\dwSize = SizeOf(PROCESSENTRY32)
  ClearList(ProcList())
  
  hthSnapshot = CreateToolhelp32Snapshot_(#TH32CS_SNAPPROCESS, 0)
  If hthSnapshot
    Process32First_(hthSnapshot, @pe32) 
    While Process32Next_(hthSnapshot, @pe32) 
      If AddElement(ProcList())
        ProcList()\Name = LCase(PeekS(@pe32\szExeFile))
        ProcList()\PID  = pe32\th32ProcessID
      EndIf
    Wend 
    CloseHandle_(hthSnapshot)
  EndIf
  
EndProcedure
 
Procedure EnumProcedure(hWnd, *Parameter.Integer)
  Protected Title.s{1024}, Res = #True, PID, ProcName.s
  If GetWindowText_(hWnd, @Title, 1024) > 0
    If GetWindowThreadProcessId_(hWnd, @PID)
      
      ProcName=""
      ForEach ProcList() ; Поиск окна которому принадлежит процесс.
        If ProcList()\PID = PID
          ProcName = ProcList()\Name
          Break
        EndIf
      Next
      
      If ProcName="notepad.exe"
        Res = #False
        *Parameter\i = #True
      EndIf
    EndIf
  EndIf
  ProcedureReturn Res
EndProcedure 
 
ProcessList() ; Список процессов.
 
IsNotepad = #False
EnumWindows_(@EnumProcedure(), @IsNotepad)
 
If IsNotepad
  Debug "Окно блокнота найдено"
Else
  Debug "Окно блокнота не найдено"
EndIf

@winkot · 26.10.2024, 18:10 **[ТС]**

Спасибо! То, что надо. А есть ли возможность управлять найденным окном? Например, сделать его активным, послать ему нажатие Enter или другую клавиатурную команду?

@locm · 26.10.2024, 20:29

Автоматизацию окон проще будет сделать через библиотеку PureAutoIt.
Запуск блокнота и активация его окна.

PureBasic
1
2
3
4
5
6
7
8
9
10
XIncludeFile "PureAutoIt.pbi"
UseModule PureAutoIt
 
; Run Notepad
Run("notepad.exe")
; Wait 10 seconds for the Notepad window to appear.
hWnd.s = Str(WinWait("[CLASS:Notepad]", "", 10))
 
; Activate the Notepad window using the handle returned by WinWait.
WinActivate(hWnd)

Ввод текста.

PureBasic
1
2
3
4
5
6
7
8
9
10
XIncludeFile "PureAutoIt.pbi"
UseModule PureAutoIt
 
; Run Notepad
Run("notepad.exe")
; Wait 10 seconds for the Notepad window to appear.
WinWait("[CLASS:Notepad]", "", 10)
 
; Simulate entering the following string and pressing the 'F5' key to input the date and time into edit control of Notepad.
Send("Текущие время и дата {F5}{Enter}")

@winkot · 27.10.2024, 18:48 **[ТС]**

Сообщение от locm

PureAutoIt.zip (168.8 Кб, 6 просмотров)

Подскажите, пожалуйста, как установить эту библиотеку в PureBasic.

@locm · 27.10.2024, 20:25

Ее не нужно устанавливать.
Из архива копируете файлы PureAutoIt.pbi, PureAutoItW.obj и PureAutoItW64.obj в папку куда сохранили файл с кодом.

@winkot · 27.10.2024, 20:35 **[ТС]**

Сообщение от locm

Из архива копируете файлы PureAutoIt.pbi, PureAutoItW.obj и PureAutoItW64.obj в папку куда сохранили файл с кодом.

А XIncludeFile и UseModule PureAutoIt надо в коде прописывать?

@locm · 27.10.2024, 20:51

Сообщение от winkot

А XIncludeFile и UseModule PureAutoIt надо в коде прописывать?

Да.
XIncludeFile подключает другой исходный файл к текущему.
UseModule позволяет использовать содержимое из указанного пространства имен без обязательного указания имени. Без последнего можно обойтись, но тогда придется указывать имя модуля.

PureBasic
1
2
3
4
5
6
7
8
XIncludeFile "PureAutoIt.pbi"
 
; Run Notepad
PureAutoIt::Run("notepad.exe")
; Wait 10 seconds for the Notepad window to appear.
hWnd.s = Str(PureAutoIt::WinWait("[CLASS:Notepad]", "", 10))
; Activate the Notepad window using the handle returned by WinWait.
PureAutoIt::WinActivate(hWnd)

А если открыть файл PureAutoIt.pbi и скопировать его содержимое, а после вставить в файл с кодом, то можно и без XIncludeFile обойтись.

@winkot · 27.10.2024, 21:13 **[ТС]**

AutoIt язык интерпретируемый. Что же получается когда мы используем его в PureBasic? Функции AutoIt вставляются в exe файл вместе с интерпретатором?

@locm · 27.10.2024, 21:23

Сообщение от winkot

Что же получается когда мы используем его в PureBasic? Функции AutoIt вставляются в exe файл вместе с интерпретатором?

Нет. От AutoIt только название, т. к. функции максимально похожи (имена и назначение). В остальном никакой связи нет.
Просто откройте файл в любом текстовом редакторе и посмотрите его.

@winkot · 27.10.2024, 21:33 **[ТС]**

Сообщение от locm

От AutoIt только название

Что то я совсем запутался. Т.е. это только имитация AutoIt? Это просто функции? написанные на PB по синтаксису похожем на AutoIt? Но почему же тогда exe файл с одной лишь функцией от AutoIt весит 1Мб, в то время как файл с такой же функцией на PB весит 200 кБ?

@locm · 27.10.2024, 21:45

Сообщение от winkot

Это просто функции? написанные на PB по синтаксису похожем на AutoIt?

Да.

Сообщение от winkot

Но почему же тогда exe файл с одной лишь функцией от AutoIt весит 1Мб, в то время как файл с такой же функцией на PB весит 200 кБ?

AutoIt интерпретируемый и exe файл содержит интерпретатор и все функции, а не только те что используются. То есть в exe файл добавляется исходный код который выполняется при запуске.
PureBasic компилируемый и exe файл создается из исходного кода и в нем только используемые функции, а не все. Тем самым размер напрямую зависит от кода.

@winkot · 28.10.2024, 09:06 **[ТС]**

Наверное я не точно задал вопрос. Я имел виду несколько иное. Создаю простейшую функцию Beep. Если это сделать средствами PB, то получится такой скрипт:

Code
1
Beep_(500,1000)

В скомпилированном виде exe файл весит 143 кБ. Если такую же функцию реализовать с помощью PureAutoIt то получится скрипт:

Code
1
2
3
4
5
6
XIncludeFile "PureAutoIt.pbi"
UseModule PureAutoIt
 
; plays back a beep noise, at the frequency 500 for 1 second
 
Beep(500, 1000)

В скомпилированном виде он весит 546 Кб. Почему же такая разница? Если исходить из того, что PureAutoIt использует те же функции, что и сам PB и только изменяет их синтаксис, то такой разницы не должно быть. А она есть.

@locm · 28.10.2024, 13:23

Сообщение от winkot

В скомпилированном виде exe файл весит 143 кБ.

Если компилировать версии 6.04 или более ранней, размер 2 КБ если это имеет значение.

Сообщение от winkot

В скомпилированном виде он весит 546 Кб.

В исполняемый файл попадают и другие функции из PureAutoIt.pbi.
Из-за них увеличивается размер.

@winkot · 28.10.2024, 15:40 **[ТС]**

Сообщение от locm

В исполняемый файл попадают и другие функции из PureAutoIt.pbi.
Из-за них увеличивается размер.

Спасибо! Теперь ясно.

Сообщение от locm

Если компилировать версии 6.04 или более ранней, размер 2 КБ

Вот это вы меня удивили! Я пользуюсь PB 6.12 и, соответственно, его же компилятором. А можно скачать отдельно компилятор версии 6.04? И еще вопрос - что же такое и ради чего разработчики сделали в более поздних компиляторах, что размер исполняемого файла увеличился в 70 раз(!) ? И ради чего это сделали?

@locm · 28.10.2024, 18:27

Сообщение от winkot

А можно скачать отдельно компилятор версии 6.04?

На официальном сайте в музее версий ~~или на рутрекере~~.

Сообщение от winkot

что же такое и ради чего разработчики сделали в более поздних компиляторах, что размер исполняемого файла увеличился в 70 раз(!) ?

https://www.purebasic.fr/blog/?p=538
Если кратко, для добавления новых функций потребовалась более свежая версия Си рантайма. Раньше она подключалась динамически (MSVCRT.dll) что существенно уменьшало размер, а начиная с версии 6.10, подключается статически.

@locm · 28.10.2024, 19:45

Адаптировал файл PureAutoIt.pbi под C backend.
Размер немного меньше стал. Файл с вызовом функции Beep имеет размер 33 КБ, а не 390 КБ.

Новые блоги и статьи Все статьи Все блоги /
SDL3 для Web (WebAssembly): Идентификация объектов на Box2D v3 - использование userData и событий коллизий 8Observer8 02.03.2026 Содержание блога Финальная демка в браузере. Итоговый код: finish-collision-events-sdl3-c. zip https:/ / www. cyberforum. ru/ blog_attachment. php?attachmentid=11680&d=1772460536 Одним из. . .	Реалии Hrethgir 01.03.2026 Нет, я не закончил до сих пор симулятор. Эта задача сложнее. Не получилось уйти в плавсостав, но оно и к лучшему, возможно. Точнее получалось - но сварщиком в палубную команду, а это значит, в моём. . .	Ритм жизни kumehtar 27.02.2026 Иногда приходится жить в ритме, где дел становится всё больше, а вовлечения в происходящее — всё меньше. Плотный график не даёт вниманию закрепиться ни на одном событии. Утро начинается с быстрых,. . .	SDL3 для Web (WebAssembly): Сборка библиотек: SDL3, Box2D, FreeType, SDL3_ttf, SDL3_mixer и SDL3_image из исходников с помощью CMake и Emscripten 8Observer8 27.02.2026 Недавно вышла версия 3. 4. 2 библиотеки SDL3. На странице официальной релиза доступны исходники, готовые DLL (для x86, x64, arm64), а также библиотеки для разработки под Android, MinGW и Visual Studio. . . .
SDL3 для Web (WebAssembly): Реализация движения на Box2D v3 - трение и коллизии с повёрнутыми стенами 8Observer8 20.02.2026 Содержание блога Box2D позволяет легко создать главного героя, который не проходит сквозь стены и перемещается с заданным трением о препятствия, которые можно располагать под углом, как верхнее. . .	Конвертировать закладки radiotray-ng в m3u-плейлист damix 19.02.2026 Это можно сделать скриптом для PowerShell. Использование . \СonvertRadiotrayToM3U. ps1 <path_to_bookmarks. json> Рядом с файлом bookmarks. json появится файл bookmarks. m3u с результатом. # Check if. . .	Семь CDC на одном интерфейсе: 5 U[S]ARTов, 1 CAN и 1 SSI Eddy_Em 18.02.2026 Постепенно допиливаю свою "многоинтерфейсную плату". Выглядит вот так: https:/ / www. cyberforum. ru/ blog_attachment. php?attachmentid=11617&stc=1&d=1771445347 Основана на STM32F303RBT6. На борту пять. . .	Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .

Открыто ли окно?

Решение

Решение

Решение

@winkot 0 / 0 / 0 Регистрация: 26.10.2024 Сообщений: 70

	Открыто ли окно? 26.10.2024, 09:48. Показов 1151. Ответов 16 Метки нет (Все метки) Как определить открыто ли окно? Например, Блокнот? Я так понимаю, что надо использовать Result = IsWindow(#Window). Но что подставить в качестве #Window? 0

@winkot 0 / 0 / 0 Регистрация: 26.10.2024 Сообщений: 70
	26.10.2024, 18:10 [ТС]
	Спасибо! То, что надо. А есть ли возможность управлять найденным окном? Например, сделать его активным, послать ему нажатие Enter или другую клавиатурную команду? 0

@winkot 0 / 0 / 0 Регистрация: 26.10.2024 Сообщений: 70
	27.10.2024, 21:13 [ТС]
	AutoIt язык интерпретируемый. Что же получается когда мы используем его в PureBasic? Функции AutoIt вставляются в exe файл вместе с интерпретатором? 0