Выделение участка изображения в PictureBox

       Dim g As Graphics
 
        Dim bmp As New Bitmap(PictureBox1.Image)
 
        g = Graphics.FromImage(bmp) 
 
        Dim pen As New Pen(Color.Red, 3)
 
        g.DrawRectangle(pen, rect)

Private Sub PictureBox1_MouseMove(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles PictureBox1.MouseMove
        
            if e.X = PozX then ' если курсор подошёл к позиции Х прямоугольника  (PozX) совершить действие
            
end sub

Public Class UC
    Inherits UserControl
 
    Private _MouseDown As Boolean = False
    Private _Coords As Point
    Private _Rectangle As Rectangle
 
    Private _Image As Bitmap
    Public Property Image As Bitmap
        Get
            Return _Image
        End Get
        Set(ByVal value As Bitmap)
            _Image = value
            Me.Refresh()
        End Set
    End Property
 
    Private _Clip As Bitmap
    Public ReadOnly Property Clip As Bitmap
        Get
            Return _Clip
        End Get
    End Property
 
    Sub New()
        Me.SetStyle(ControlStyles.OptimizedDoubleBuffer, True)
        Me.SetStyle(ControlStyles.UserPaint, True)
        Me.SetStyle(ControlStyles.AllPaintingInWmPaint, True)
    End Sub
 
    Protected Overrides Sub OnMouseDown(ByVal e As System.Windows.Forms.MouseEventArgs)
        'MyBase.OnMouseDown(e)
 
        _MouseDown = True
        _Coords = e.Location
 
        If Not _Rectangle.Contains(_Coords) And _Clip IsNot Nothing Then
            Graphics.FromImage(_Image).DrawImage(_Clip, _Rectangle)
            _Clip = Nothing
            _Rectangle = Nothing
            Me.Refresh()
        End If
    End Sub
    Protected Overrides Sub OnMouseUp(ByVal e As System.Windows.Forms.MouseEventArgs)
        'MyBase.OnMouseUp(e)
 
        _MouseDown = False
 
        If _Rectangle.Width > 0 And _Rectangle.Height > 0 And _Clip Is Nothing Then
            _Clip = New Bitmap(_Rectangle.Width, _Rectangle.Height, Imaging.PixelFormat.Format32bppArgb)
            Graphics.FromImage(_Clip).DrawImage(_Image, _
                                                New Rectangle(0, 0, _Rectangle.Width, _Rectangle.Height), _
                                                _Rectangle, _
                                                GraphicsUnit.Pixel)
        End If
    End Sub
 
    Protected Overrides Sub OnMouseMove(ByVal e As System.Windows.Forms.MouseEventArgs)
        'MyBase.OnMouseMove(e)
 
        If _MouseDown Then
            Dim c As Point = e.Location
            Dim w As Integer = c.X - _Coords.X
            Dim h As Integer = c.Y - _Coords.Y
 
            If _Clip IsNot Nothing Then
                _Rectangle.X += w
                _Rectangle.Y += h
                _Coords = c
 
            Else
 
                If w <> 0 And h <> 0 Then
                    _Rectangle = New Rectangle(If(w > 0, _Coords.X, c.X), _
                                               If(h > 0, _Coords.Y, c.Y), _
                                               Math.Abs(w), _
                                               Math.Abs(h))
                End If
 
            End If
 
            Me.Refresh()
        End If
    End Sub
 
    Protected Overrides Sub OnPaint(ByVal e As System.Windows.Forms.PaintEventArgs)
        MyBase.OnPaint(e)
 
        If _Image IsNot Nothing Then e.Graphics.DrawImage(_Image, 0, 0, _Image.Width, _Image.Height)
 
        If _Clip IsNot Nothing Then e.Graphics.DrawImage(_Clip, _Rectangle)
 
        If _Rectangle <> Nothing Then
            Dim p As New Pen(Color.Cyan, 1)
            p.DashStyle = DashStyle.Dash
            e.Graphics.DrawRectangle(p, _Rectangle)
            p.Dispose()
        End If
    End Sub
End Class

Public Class RubberBand 
    ' ----- The three types of rubber bands. 
    Public Enum RubberBandStyle 
        DashedLine 
        ThickLine 
        SolidBox 
        SolidBoxWithDashedLine 
    End Enum 
 
    ' ----- The current drawing state. 
    Public Enum RubberBandState 
        Inactive 
        FirstTime 
        Active 
    End Enum 
 
    ' ----- Class-level variables. 
    Private BasePoint As Point 
    Private ExtentPoint As Point 
    Private CurrentState As RubberBandState 
    Private BaseControl As Control 
    Public Style As RubberBandStyle 
    Public BackColor As Color 
    Public Sub New(ByVal useControl As Control, _ 
          Optional ByVal useStyle As RubberBandStyle = _ 
          RubberBandStyle.DashedLine) 
        ' ----- Constructor with one or two parameters. 
        BaseControl = useControl 
        Style = useStyle 
        BackColor = Color.Black 
    End Sub 
 
    Public Sub New(ByVal useControl As Control, ByVal useStyle As RubberBandStyle, ByVal useColor As Color) 
        ' ----- Constructor with three parameters. 
        BaseControl = useControl 
        Style = useStyle 
        BackColor = useColor 
    End Sub 
 
    Public ReadOnly Property Rectangle() As Rectangle 
        Get 
            ' ----- Return the bounds of the  rubber-band area. 
            Dim result As Rectangle 
 
            ' ----- Ensure the coordinates go left to 
            ' right, top to bottom. 
            result.X = IIf(BasePoint.X < ExtentPoint.X, _ 
               BasePoint.X, ExtentPoint.X) 
            result.Y = IIf(BasePoint.Y < ExtentPoint.Y, _ 
               BasePoint.Y, ExtentPoint.Y) 
            result.Width = Math.Abs(ExtentPoint.X - BasePoint.X) 
            result.Height = Math.Abs(ExtentPoint.Y - BasePoint.Y) 
            Return result 
        End Get 
    End Property 
 
    Public Sub Start(ByVal x As Integer, ByVal y As Integer) 
        ' ----- Start drawing the rubber band. The user must 
        '       call Stretch() to actually draw the first 
        '       band image. 
        BasePoint.X = x 
        BasePoint.Y = y 
        ExtentPoint.X = x 
        ExtentPoint.Y = y 
        Normalize(BasePoint) 
        CurrentState = RubberBandState.FirstTime 
    End Sub 
 
    Public Sub Stretch(ByVal x As Integer, ByVal y As Integer) 
        ' ----- Change the size of the rubber band. 
        Dim newPoint As Point 
 
        ' ----- Prepare the new stretch point. 
        newPoint.X = x 
        newPoint.Y = y 
        Normalize(newPoint) 
 
        Select Case CurrentState 
            Case RubberBandState.Inactive 
                ' ----- Rubber band not in use. 
                Return 
            Case RubberBandState.FirstTime 
                ' ----- Draw the initial rubber band. 
                ExtentPoint = newPoint 
                DrawTheRectangle() 
                CurrentState = RubberBandState.Active 
            Case RubberBandState.Active 
                ' ----- Undraw the previous band, then 
                '       draw the new one. 
                DrawTheRectangle() 
                ExtentPoint = newPoint 
                DrawTheRectangle() 
        End Select 
    End Sub 
 
    Public Sub Finish() 
        ' ----- Stop drawing the rubber band. 
        DrawTheRectangle() 
        CurrentState = 0 
    End Sub 
 
    Private Sub Normalize(ByRef whichPoint As Point) 
        ' ----- Don't let the rubber band go outside the view. 
        If (whichPoint.X < 0) Then whichPoint.X = 0 
        If (whichPoint.X >= BaseControl.ClientSize.Width) Then whichPoint.X = BaseControl.ClientSize.Width - 1 
 
        If (whichPoint.Y < 0) Then whichPoint.Y = 0 
        If (whichPoint.Y >= BaseControl.ClientSize.Height) Then whichPoint.Y = BaseControl.ClientSize.Height - 1 
    End Sub 
 
    Private Sub DrawTheRectangle() 
        ' ----- Draw the rectangle on the control or 
        '       form surface. 
        Dim drawArea As Rectangle 
        Dim screenStart, screenEnd As Point 
 
        ' ----- Get the square that is the  rubber-band area. 
        screenStart = BaseControl.PointToScreen(BasePoint) 
        screenEnd = BaseControl.PointToScreen(ExtentPoint) 
        drawArea.X = screenStart.X 
        drawArea.Y = screenStart.Y 
        drawArea.Width = (screenEnd.X - screenStart.X) 
        drawArea.Height = (screenEnd.Y - screenStart.Y) 
 
        ' ----- Draw using the user-selected style. 
        Select Case Style 
            Case RubberBandStyle.DashedLine 
                ControlPaint.DrawReversibleFrame( _ 
                   drawArea, BackColor, FrameStyle.Dashed) 
            Case RubberBandStyle.ThickLine 
                ControlPaint.DrawReversibleFrame( _ 
                   drawArea, BackColor, FrameStyle.Thick) 
            Case RubberBandStyle.SolidBox 
                ControlPaint.FillReversibleRectangle( _ 
                   drawArea, BackColor) 
            Case RubberBandStyle.SolidBoxWithDashedLine 
                ControlPaint.FillReversibleRectangle( _ 
                   drawArea, BackColor) 
                ControlPaint.DrawReversibleFrame( _ 
                   drawArea, Color.Black, FrameStyle.Dashed) 
        End Select 
    End Sub 
End Class

Friend SelectionArea As RubberBand

SelectionArea = New RubberBand(Me.Poligon, RubberBand.RubberBandStyle.DashedLine, Color.FromArgb(255, 0, 255))

SelectionArea.Start(e.X, e.Y)

If e.Button = Windows.Forms.MouseButtons.Left Then 
            SelectionArea.Stretch(e.X, e.Y) 
        End If

SelectionArea.Finish()