Класс прорисовки трапеций

@Pr1 · Регистрация: 26.07.2017

Студворк — интернет-сервис помощи студентам

здравствуйте! помогите, пожалуйста, создать класс закрашенных трапеций, так чтобы потом можно было нарисовать несколько экземпляров этого класса и перемещать их по окошку формы.

@ovva · 01.05.2018, 20:27

Pr1, простой пример реализации графических примитивов на форме. Управление:
Создание объекта - двойной клик ЛКМ на форме
Перемещение объекта – перемещать при нажатой и удерживаемой на объекте ЛКМ
Поворот объекта на 90 гр. – клик на объекте ПКМ
Форма:

VB.NET
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Public Class Form1
    Private Sub Form1_MouseDoubleClick(sender As System.Object, e As System.Windows.Forms.MouseEventArgs) Handles MyBase.MouseDoubleClick
        Static nm As Integer = 1
        Dim pts() As Point
        'pts = {New Point(0, 0), New Point(50, 0), New Point(50, 30), New Point(0, 30)} 'прямоугольник
        'pts = {New Point(0, 100), New Point(100, 100), New Point(50, 0)} 'треугольник
        pts = {New Point(0, 100), New Point(200, 100), New Point(150, 0), New Point(50, 0)} 'трапеция и т.д.
        Dim ob As New Shape(e.X, e.Y, Color.LightGreen)
        With ob
            .Name = "sh" & nm.ToString
            .setShape(pts)
        End With
        nm += 1
        Me.Controls.Add(ob)
    End Sub
End Class

Класс:

Кликните здесь для просмотра всего текста

VB.NET
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
Imports System.Drawing.Drawing2D
Public Class Shape
    Inherits Control
    Private pp() As Point
    Private bkColorOld As Color
    Private dragging As Boolean
    Private pointClicked, correction As Point
    Public Sub New()
        MyBase.New()
        Me.Width = 10
        Me.Height = 10
        _bkColorDown = Color.Aqua
    End Sub
    Public Sub New(ByVal x As Integer, ByVal y As Integer, ByVal bk As Color)
        Me.New()
        Me.Location = New Point(x, y) 'привязка объекта
        Me.BackColor = bk 'цвет объекта
    End Sub
    Public Property bkColorDown As Color 'цвет объекта при перемещении
    Public Sub setShape(ByVal pnt() As Point)
        pp = pnt
        Dim pgPath As New GraphicsPath(FillMode.Winding)
        pgPath.AddPolygon(pp)
        Me.Region = New Region(pgPath)
        Dim re As RectangleF = pgPath.GetBounds
        Me.SetBounds(Me.Location.X, Me.Location.Y, re.Width + re.Width / 3, re.Height + re.Height / 3)
    End Sub
    Protected Overrides Sub OnMouseDown(pe As System.Windows.Forms.MouseEventArgs)
        dragging = False
        If pe.Button = Windows.Forms.MouseButtons.Left Then
            bkColorOld = Me.BackColor
            Me.BackColor = bkColorDown
            dragging = True
            pointClicked = New Point(Me.Location.X + pe.X, Me.Location.Y + pe.Y)
            correction = New Point(pe.X, pe.Y)
        Else
            rotate90()
        End If
    End Sub
    Protected Overrides Sub OnMouseMove(pe As System.Windows.Forms.MouseEventArgs)
        If dragging Then
            pointClicked.Offset(New Point(pe.X, pe.Y))
            pointClicked.Offset(-correction.X, -correction.Y)
            Me.Location = pointClicked
        End If
    End Sub
    Protected Overrides Sub OnMouseUp(pe As System.Windows.Forms.MouseEventArgs)
        If dragging Then Me.BackColor = bkColorOld
        dragging = False
    End Sub
    Private Sub rotate90()
        Dim cs, sn, xx, yy As Integer
        Dim mnx As Integer = Integer.MaxValue, mny As Integer = Integer.MaxValue
        Static dgr As Integer = 0
        dgr += 90
        If dgr = 360 Then dgr = 0
        Dim ppp() As Point = pp.Clone
        Dim rr As Double = dgr * Math.PI / 180
        cs = Math.Cos(rr)
        sn = Math.Sin(rr)
        For i = 0 To pp.Length - 1
            xx = ppp(i).X * cs - ppp(i).Y * sn
            yy = ppp(i).X * sn + ppp(i).Y * cs
            ppp(i).Y = yy
            ppp(i).X = xx
            If ppp(i).X < mnx Then mnx = ppp(i).X
            If ppp(i).Y < mny Then mny = ppp(i).Y
        Next
        For i = 0 To pp.Length - 1
            ppp(i).Offset(-mnx, -mny)
        Next
        Dim pgPath As New GraphicsPath(FillMode.Winding)
        pgPath.AddPolygon(ppp)
        Me.Region = New Region(pgPath)
        Dim re As RectangleF = pgPath.GetBounds
        Me.SetBounds(Me.Location.X, Me.Location.Y, re.Width + 5, re.Height + 5)
    End Sub
End Class

@Pr1 · 02.06.2018, 18:12 **[ТС]**

а как реализовать случайное перемещение одновременно нескольких объектов этого класса, например, при нажатии F1?

Добавлено через 45 минут
и как потом удалить созданные объекты?

@ovva · 03.06.2018, 14:31

Добавьте две кнопки на Form1 (привязать к F1 или какой другой клавише, полагаю, сможете и сами).

VB.NET
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Private Sub Delete_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
    For i = Me.Controls.Count - 1 To 0 Step -1
        Dim sh As Control = Me.Controls(i)
        If TypeOf sh Is Shape Then
            Me.Controls.Remove(sh)
        End If
    Next
End Sub
Private Sub rndLocation_Click(sender As System.Object, e As System.EventArgs) Handles Button2.Click
    Dim x, y As Integer
    Dim cc As Color
    Dim rnd As New Random
    For i = 0 To Me.Controls.Count - 1
        Dim sh As Control = Me.Controls(i)
        If TypeOf sh Is Shape Then
            x = rnd.Next(0, Me.Width - sh.Width)
            y = rnd.Next(0, Me.Height - sh.Height)
            cc = Color.FromArgb(rnd.Next(0, 256), rnd.Next(0, 256), rnd.Next(0, 256))
            sh.Location = New Point(x, y)
            sh.BackColor = cc
        End If
    Next
End Sub

Новые блоги и статьи Все статьи Все блоги /
SDL3 для Web (WebAssembly): Обработчик клика мыши в браузере ПК и касания экрана в браузере на мобильном устройстве 8Observer8 02.02.2026 Содержание блога Для начала пошагово создадим рабочий пример для подготовки к экспериментам в браузере ПК и в браузере мобильного устройства. Потом напишем обработчик клика мыши и обработчик. . .	Философия технологии iceja 01.02.2026 На мой взгляд у человека в технических проектах остается роль генерального директора. Все остальное нейронки делают уже лучше человека. Они не могут нести предпринимательские риски, не могут. . .	SDL3 для Web (WebAssembly): Вывод текста со шрифтом TTF с помощью SDL3_ttf 8Observer8 01.02.2026 Содержание блога В этой пошаговой инструкции создадим с нуля веб-приложение, которое выводит текст в окне браузера. Запустим на Android на локальном сервере. Загрузим Release на бесплатный. . .	SDL3 для Web (WebAssembly): Сборка C/C++ проекта из консоли 8Observer8 30.01.2026 Содержание блога Если вы откроете примеры для начинающих на официальном репозитории SDL3 в папке: examples, то вы увидите, что все примеры используют следующие четыре обязательные функции, а. . .
SDL3 для Web (WebAssembly): Установка Emscripten SDK (emsdk) и CMake для сборки C и C++ приложений в Wasm 8Observer8 30.01.2026 Содержание блога Для того чтобы скачать Emscripten SDK (emsdk) необходимо сначало скачать и уставить Git: Install for Windows. Следуйте стандартной процедуре установки Git через установщик. . . .	SDL3 для Android: Подключение Box2D v3, физика и отрисовка коллайдеров 8Observer8 29.01.2026 Содержание блога Box2D - это библиотека для 2D физики для анимаций и игр. С её помощью можно определять были ли коллизии между конкретными объектами. Версия v3 была полностью переписана на Си, в. . .	Инструменты COM: Сохранение данный из VARIANT в файл и загрузка из файла в VARIANT bedvit 28.01.2026 Сохранение базовых типов COM и массивов (одномерных или двухмерных) любой вложенности (деревья) в файл, с возможностью выбора алгоритмов сжатия и шифрования. Часть библиотеки BedvitCOM Использованы. . .	SDL3 для Android: Загрузка PNG с альфа-каналом с помощью SDL_LoadPNG (без SDL3_image) 8Observer8 28.01.2026 Содержание блога SDL3 имеет собственные средства для загрузки и отображения PNG-файлов с альфа-каналом и базовой работы с ними. В этой инструкции используется функция SDL_LoadPNG(), которая. . .

@Pr1 0 / -1 / 0 Регистрация: 26.07.2017 Сообщений: 33

	Класс прорисовки трапеций 01.05.2018, 14:52. Показов 1557. Ответов 3 Метки нет (Все метки) здравствуйте! помогите, пожалуйста, создать класс закрашенных трапеций, так чтобы потом можно было нарисовать несколько экземпляров этого класса и перемещать их по окошку формы. 0

@Pr1 0 / -1 / 0 Регистрация: 26.07.2017 Сообщений: 33
	02.06.2018, 18:12 [ТС]
	а как реализовать случайное перемещение одновременно нескольких объектов этого класса, например, при нажатии F1? Добавлено через 45 минут и как потом удалить созданные объекты? 0

Класс прорисовки трапеций

Решение