Чтение конкретных строк из txt (2 - 5)

Option Explicit
 
Sub SampleReading()
    Dim i As Long
    Dim strContent As String
    
    
    With CreateObject("Scripting.FileSystemObject")
        strContent = ""
        
        With .OpenTextFile("c:\Windows\win.ini")
            .SkipLine
            
            For i = 2 To 5
                strContent = strContent & .ReadLine() & vbCrLf
            Next
            
            MsgBox strContent
            
            .Close
        End With
    End With
End Sub

Sub SampleReading()
    
    'Здесь нужно указать путь и имя текстового файла.
    Const sFilePath As String = "C:\Users\User\Desktop\Текстовый документ.txt"
 
    Dim i As Long
    Dim strContent As String
    
    'Для позднего связывания: "Scripting.FileSystemObject".
    Dim oFSO As New IWshRuntimeLibrary.FileSystemObject
    Dim oTextFile As IWshRuntimeLibrary.TextStream
 
    Set oTextFile = oFSO.OpenTextFile(sFilePath)
 
    'Переход к нужной строке.
    For i = 1 To 3 Step 1
        oTextFile.SkipLine
    Next i
 
    'Взятие данных из нужных строк.
    For i = 4 To 7 Step 1
        strContent = strContent & oTextFile.ReadLine & Chr(13)
    Next i
 
    'Закрытие текстового файла.
    oTextFile.Close
    
    MsgBox strContent
 
End Sub

Function StringsFromFile(sPath$, Optional nFrom = 1, Optional nTo = 2147000000) As String
 
'Функция возвращает строки из файла sPath, с nFrom по nTo
'Если nFrom опущен, возвращает текст с 1-й строки
'Если nTo опущен, возвращает до конца файла
'https://www.cyberforum.ru/vba/thread656180.html
 
Dim k%, i&, d$
k = FreeFile
On Error GoTo err_
Open sPath For Input Access Read As k
For i = 1 To nTo
    Line Input #k, d
    If i >= nFrom Then StringsFromFile = StringsFromFile & d & vbCrLf
Next
ex_: Close k
Exit Function
 
err_: Resume ex_
End Function
 
Sub test()
Debug.Print ">" & StringsFromFile("d:\строки.txt") & "<"        'весь файл
Debug.Print ">" & StringsFromFile("d:\строки.txt", 4) & "<"     'с 4-й строки до конца
Debug.Print ">" & StringsFromFile("d:\строки.txt", , 4) & "<"   '1-4 строки
Debug.Print ">" & StringsFromFile("d:\строки.txt", 10) & "<"    'пустая строка
Debug.Print ">" & StringsFromFile("w:\erty", 4) & "<"           'пустая строка
End Sub