VB.NET Динамическая загрузка WebView2 контрола в ваш проект (часть 2)

    Private Class NativeMethods
        <DllImport("kernel32.dll", CharSet:=CharSet.Unicode, SetLastError:=True)>
        Public Shared Function AddDllDirectory(path As String) As IntPtr
        End Function
 
        <DllImport("kernel32.dll", CharSet:=CharSet.Unicode, SetLastError:=True)>
        Public Shared Function LoadLibrary(lpFileName As String) As IntPtr
        End Function
    End Class

   Private Sub AutoReg()
       ' Загрузка нативной DLL через Windows API
 
 
       Dim result As IntPtr = NativeMethods.AddDllDirectory(Path.GetDirectoryName(LibFiles(2)))
 
       If result = IntPtr.Zero Then
           Dim errorCode = Marshal.GetLastWin32Error()
           ShowCriticalError($"Ошибка AddDllDirectory: код ошибки {errorCode}")
       End If
 
       Dim libraryHandle As IntPtr = NativeMethods.LoadLibrary(LibFiles(2))
 
       If libraryHandle = IntPtr.Zero Then
           Dim errorCode = Marshal.GetLastWin32Error()
           ShowCriticalError($"Ошибка LoadLibrary: код ошибки {errorCode}")
       End If
 
       ' Загрузка управляемых сборок через Reflection
 
       CoreAssembly = Assembly.LoadFrom(LibFiles(0))
       If CoreAssembly Is Nothing Then
           ShowCriticalError("Сборка WebView2 Core не загружена")
       End If
 
       WinFormsAssembly = Assembly.LoadFrom(LibFiles(1))
       If WinFormsAssembly Is Nothing Then
           ShowCriticalError("Сборка WebView2 WinForms не загружена")
       End If
 
   End Sub

    Public CoreAssembly As Assembly
    Public WinFormsAssembly As Assembly

Imports System.IO
Imports System.IO.Compression
Imports System.Reflection
Imports System.Runtime.InteropServices
 
Public Class DynamicWebView2Loader
    Private ReadOnly isDevelopment As Boolean = True
 
    Private LibFiles As String() ' это сгенерированный массив в котором хранятся   прямые ссылки на файлы зависимостей
 
    Public CoreAssembly As Assembly
 
    Public WinFormsAssembly As Assembly
    Private Sub ShowCriticalError(message As String, Optional ex As Exception = Nothing)
        Dim errorMessage As String
        If isDevelopment Then
            errorMessage = $"{message}{vbCrLf}{If(ex IsNot Nothing, "Детали: " & ex.ToString(), "Детали отсутствуют")}"
        Else
            errorMessage = $"Дальнейшее выполнение программы невозможно.{vbCrLf}Обратитесь в службу поддержки."
        End If
 
        MessageBox.Show(errorMessage, "Критическая ошибка", MessageBoxButtons.OK, MessageBoxIcon.Error)
        Application.Exit()
    End Sub
 
    Public Sub New()
        ' приступаем к формированию ссылок 
 
        Dim resName As String = NameOf(My.Resources._2_1_0_3537_50).TrimStart("_"c).Replace("_"c, "."c) ' так только ленивые делают, вроде меня;) 
        Dim libDir As String = Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.LocalApplicationData), Me.GetType().Name)
        Dim verDir As String = libDir & Path.DirectorySeparatorChar & resName
        Dim ldrDir As String = Path.Combine(verDir, "runtimes", "win-x86", "native")
        '  ссылки на папки сформированы... пора их создать, если они конечно ещё не существуют
        Directory.CreateDirectory(libDir)
        Directory.CreateDirectory(verDir)
 
        LibFiles = {
                Path.Combine(verDir, "Microsoft.Web.WebView2.Core.dll"),
                Path.Combine(verDir, "Microsoft.Web.WebView2.WinForms.dll"),
                Path.Combine(ldrDir, "WebView2Loader.dll")}
        ' проверим и если файлы не сушествуют... распаковываем их из ресурсов 
        If Not FilesExist(LibFiles) Then
            Extract(verDir, My.Resources._2_1_0_3537_50)
        End If
        AutoReg()
    End Sub
 
 
 
    Private Function FilesExist(stringmassive As String()) As Boolean
        Try
            Return stringmassive.All(Function(f) File.Exists(f))
        Catch ex As Exception
            Return False
        End Try
    End Function
 
 
    Private Sub Extract(destinationDirectoryName As String, buffer As Byte())
        Try
            Using archive = New ZipArchive(New MemoryStream(buffer), ZipArchiveMode.Read)
                archive.ExtractToDirectory(destinationDirectoryName)
            End Using
        Catch ex As Exception
            ShowCriticalError("Ошибка распаковки", ex)
        End Try
    End Sub
    Private Class NativeMethods
        <DllImport("kernel32.dll", CharSet:=CharSet.Unicode, SetLastError:=True)>
        Public Shared Function AddDllDirectory(path As String) As IntPtr
        End Function
 
        <DllImport("kernel32.dll", CharSet:=CharSet.Unicode, SetLastError:=True)>
        Public Shared Function LoadLibrary(lpFileName As String) As IntPtr
        End Function
    End Class
 
    Private Sub AutoReg()
        ' Загрузка нативной DLL через Windows API
 
 
        Dim result As IntPtr = NativeMethods.AddDllDirectory(Path.GetDirectoryName(LibFiles(2)))
 
        If result = IntPtr.Zero Then
            Dim errorCode = Marshal.GetLastWin32Error()
            ShowCriticalError($"Ошибка AddDllDirectory: код ошибки {errorCode}")
        End If
 
        Dim libraryHandle As IntPtr = NativeMethods.LoadLibrary(LibFiles(2))
 
        If libraryHandle = IntPtr.Zero Then
            Dim errorCode = Marshal.GetLastWin32Error()
            ShowCriticalError($"Ошибка LoadLibrary: код ошибки {errorCode}")
        End If
 
        ' Загрузка управляемых сборок через Reflection
 
        CoreAssembly = Assembly.LoadFrom(LibFiles(0))
        If CoreAssembly Is Nothing Then
            ShowCriticalError("Сборка WebView2 Core не загружена")
        End If
 
        WinFormsAssembly = Assembly.LoadFrom(LibFiles(1))
        If WinFormsAssembly Is Nothing Then
            ShowCriticalError("Сборка WebView2 WinForms не загружена")
        End If
 
    End Sub
End Class

Public webView2Type As Type
Public WebView2Control

    Private Sub CreateWebView2Control()
 
        ' Получаем тип WebView2 контрола из сборки WinForms
        webView2Type = WinFormsAssembly.GetType("Microsoft.Web.WebView2.WinForms.WebView2", True)
        If webView2Type Is Nothing Then
            ShowCriticalError("Не удалось получить тип WebView2 контрола из сборки")
        End If
 
        ' Создаем экземпляр контрола через рефлексию
        WebView2Control = CType(Activator.CreateInstance(webView2Type), Control)
        If WebView2Control Is Nothing Then
            ShowCriticalError("Не удалось создать экземпляр WebView2 контрола")
        End If
    End Sub

   Public Async Function InitializeWebView2Async() As Task
        Try
            ' Создаем среду выполнения WebView2
            Dim environmentType = CoreAssembly.GetType("Microsoft.Web.WebView2.Core.CoreWebView2Environment")
            If environmentType Is Nothing Then
                ShowCriticalError("Не удалось найти тип CoreWebView2Environment")
            End If
 
            ' Ищем метод CreateAsync для асинхронного создания среды
            Dim createAsyncMethod = (From m In environmentType.GetMethods(BindingFlags.Public Or BindingFlags.Static)
                                     Where m.Name = "CreateAsync" AndAlso m.GetParameters().Length = 3
                                     Select m).FirstOrDefault()
 
            If createAsyncMethod Is Nothing Then
                ShowCriticalError("Метод CreateAsync не найден в CoreWebView2Environment")
            End If
 
            ' Создаем временную директорию для кэша WebView2
 
            Dim _appCachePath = Path.Combine(Path.GetTempPath(), "WebView2App")
 
 
 
            Directory.CreateDirectory(_appCachePath)
 
            ' Асинхронно создаем среду выполнения
            Dim createTask = CType(createAsyncMethod.Invoke(Nothing, New Object() {Nothing, _appCachePath, Nothing}), Task)
 
            ' Проверка создания задачи
            If createTask Is Nothing Then
                ShowCriticalError("CreateAsync не вернул задачу")
            End If
 
            Await createTask
 
            Dim environment = createTask.GetType().GetProperty("Result").GetValue(createTask)
 
            ' Проверка результата
            If environment Is Nothing Then
                ShowCriticalError("Среда выполнения WebView2 не была создана")
            End If
 
            ' Теперь инициализируем CoreWebView2 контрола с созданной средой
            Dim ensureMethod = webView2Type.GetMethod("EnsureCoreWebView2Async",
            BindingFlags.Public Or BindingFlags.Instance,
            Nothing,
            New Type() {environmentType},
            Nothing)
 
            If ensureMethod Is Nothing Then
                ShowCriticalError("Метод EnsureCoreWebView2Async не найден")
            End If
 
            Dim ensureTask = CType(ensureMethod.Invoke(WebView2Control, New Object() {environment}), Task)
            Await ensureTask
 
 
 
 
        Catch ex As Exception
            ShowCriticalError("Ошибка инициализации WebView2:", ex)
 
        End Try
 
    End Function
 
    ' Выполняет навигацию к указанному URL
    Public Sub Navigate(url As String)
        Try
            Dim sourceProp = webView2Type.GetProperty("Source")
            If sourceProp Is Nothing Then
                ShowCriticalError("Свойство Source не найдено в WebView2 контроле")
            End If
 
            sourceProp.SetValue(WebView2Control, New Uri(url))
 
        Catch ex As Exception
            ShowCriticalError($"Ошибка навигации в WebView2", ex)
        End Try
    End Sub

Public Class Form1
    Private Browser As DynamicWebView2Loader
 
    Public Sub New()
 
        ' Dieser Aufruf ist für den Designer erforderlich.
        InitializeComponent()
 
        ' Fügen Sie Initialisierungen nach dem InitializeComponent()-Aufruf hinzu.
 
        Browser = New DynamicWebView2Loader
        Me.Controls.Add(Browser.WebView2Control)
        Browser.WebView2Control.Dock = DockStyle.Fill
    End Sub
 
    Private Async Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
 
        Await Browser.InitializeWebView2Async
        Browser.Navigate("https://www.cyberforum.ru/blogs/1794766/10620.html")
    End Sub
End Class