Реализуем вызовы HTTP API

  TNameValuePair = record
    Name: string;
    Value: string;
    constructor Create(const AName, AValue: string);
  end;
 
  TNameValueArray = TArray<TNameValuePair>;

unit UUriHelper;
 
interface
uses System.NetEncoding, System.Net.URLClient;
 
type
  TURIHelper = record helper for TURI
    function FindParameterIndex(const AName: string): Integer;
    function ParamExists(const AName:string): Boolean;
    procedure AddOrSetParamByName(const AName,AValue: string);
  end;
 
 
implementation
 
uses
  System.SysUtils;
 
{ TURIHelper }
 
procedure TURIHelper.AddOrSetParamByName(const AName, AValue: string);
var
  LIndex: Integer;
begin
  LIndex := FindParameterIndex(AName);
  if LIndex >= 0 then
    Parameter[LIndex] := TURIParameter.Create( TNetEncoding.URL.EncodeQuery(AName), TNetEncoding.URL.EncodeQuery(AValue))
  else
    AddParameter(AName, AValue);
end;
 
function TURIHelper.FindParameterIndex(const AName: string): Integer;
var
  I: Integer;
  LName: string;
begin
  Result := -1;
  LName := TNetEncoding.URL.EncodeQuery(AName);
  for I := 0 to Length(Params) - 1 do
    if Params[I].Name = LName then
      Exit(I);
end;
 
function TURIHelper.ParamExists(const AName: string): Boolean;
begin
  Result := FindParameterIndex(AName)<>-1;
end;
 
end.

function THttpApi.MakeUrl: string;
var
  s : String;
  name : String;
  i : integer;
begin
  s := IncludeTrailingPathDelimiter(BaseURL) + UrlParams.DelimitedText;
  // FURI это RECORD поэтому не нужно FURI := TUri.Create(s).
  // можно просто вызвать Create для инициализации полей
  FURI.Create(s);
  for i := 0 to QueryParams.Count-1 do
  begin
    name := QueryParams.Names[i];
    FURI.AddOrSetParamByName(name,QueryParams.Values[name]);
  end;
  result := FURI.ToString;
end;

unit HttpApi;
 
interface
uses
  System.Classes,
  System.SysUtils,
 
  system.Net.HttpClient,
  system.Net.URLClient,
 
  XSuperObject
  ;
 
type
  THttpApi = class
  protected
    FURI: TURI;
  public
    BaseURL : string;
    Headers: TNameValueArray;
    ResStream: TStringStream;
    SrcStream: TStringStream;
    Token : string;
    Response : IHTTPResponse;
    ResultString : string;
    ResultJson : ISuperObject;
 
    UrlParams : TStringList;
    QueryParams : TStringList;
 
    constructor Create(ABaseUrl: string); virtual;
    destructor Destroy(); override;
 
    procedure ClearParams;
    procedure SetHeaders(); virtual;
    function MakeUrl : string;
 
    procedure Request(AHttpMethod: string);
  end;
 
 
implementation
 
{ THttpApi }
 
constructor THttpApi.Create(ABaseUrl : string);
begin
  BaseURL := ABaseUrl;
  UrlParams := TStringList.Create;
  UrlParams.Delimiter := '/';
  QueryParams := TStringList.Create;
  QueryParams.Delimiter := '&';
  ResStream := TStringStream.Create('', TEncoding.UTF8);
  SrcStream := TStringStream.Create('', TEncoding.UTF8);
end;
 
destructor THttpApi.Destroy;
begin
  FreeAndNil(UrlParams);
  FreeAndNil(QueryParams);
  FreeAndNil(SrcStream);
  FreeAndNil(ResStream);
  inherited;
end;
 
 
function THttpApi.MakeUrl: string;
var
  s : String;
  name : String;
  i : integer;
begin
  s := IncludeTrailingPathDelimiter(BaseURL) + UrlParams.DelimitedText;
  // FURI это RECORD поэтому не нужно FURI := TUri.Create(s).
  // можно просто вызвать Create для инициализации полей
  FURI.Create(s);
  for i := 0 to QueryParams.Count-1 do
  begin
    name := QueryParams.Names[i];
    FURI.AddOrSetParamByName(name,QueryParams.Values[name]);
  end;
  result := FURI.ToString;
end;
 
// перед вызовом Request уже подготовлены все данные в SrcStream 
// и заданы UrlParams и QueruParams
procedure THttpApi.Request(AHttpMethod: string);
var
  http : THttpClient;
  url : string;
begin
  http := THttpClient.Create;
  try
 
    url := MakeUrl();
    SetHeaders();
 
    if AHttpMethod = 'POST' then
    begin
      Response := http.Post(url, SrcStream, ResStream, Headers);
    end
    else if AHttpMethod = 'GET' then
    begin
      /// Response := http.get .....
    end
    else if AHttpMethod = 'PUT' then
    begin
      /// Response := http.put .....
    end;
 
    if (Response.StatusCode div 100) <> 2 then
    begin
       // если все прошло нормально, код должен быть 2xx (201, 202...) https://ru.wikipedia.org/wiki/Список_кодов_состояния_HTTP
      raise Exception.Create('Http request error');
    end;
 
    ResultString := Response.ContentAsString(TEncoding.UTF8);
    /// Если все хорошо, то можно попытаться из ResultString получить ResultJson
    try
      ResultJson := SO(ResultString);
    except
      /// если строка - не JSON, здесь можно обработать ошибку
    end;
 
  finally
    FreeAndNil(http);
  end;
end;
 
procedure THttpApi.SetHeaders;
begin
  SetLength(Headers, 3);
  Headers[0].Name := 'Content-Type';
  Headers[0].Value := 'application/json';
  Headers[1].Name := 'Accept';
  Headers[1].Value := 'application/json';
  Headers[2].Name := 'Authorization';
  Headers[2].Value := Token;
end;
 
procedure THttpApi.ClearParams;
begin
  UrlParams.Clear;
  QueryParams.Clear;
  SrcStream.Clear;
end;
 
end.

unit My.Api;
 
interface
uses
  System.Classes,
  System.SysUtils,
 
  system.Net.HttpClient,
 
  HttpApi,
  MyClasses
  ;
 
type
  TMyApi = class(THttpApi)
  public
    constructor Create();
  end;
 
implementation
 
{ TMyApi }
 
constructor TMyApi.Create;
begin
  inherited Create('https://server.com/api/v2/');
  token := 'Bearer XXX-XXX-YYYY';
end;
 
 
end.