Змейка на бат, или как НЕ НАДО делать игры

@echo off
setlocal enabledelayedexpansion
if "%~1"=="control" goto control
cls
set /p "pause=Type pause cycles [optimal: 1000 - 10000]>"
start "CONTROL" "%~nx0" control
echo.Press any key in control window
if exist sn.cntrl erase sn.cntrl
:wait
if not exist sn.cntrl goto wait
 
call :clear
call :cepos
 
set "snake[0]X=1"
set "snake[0]Y=1"
set "snake.length=0"
set "dir=D"
 
:game
::cscript //nologo //e:jscript "%~nx0" 20
for /L %%A IN (1 1 %pause%) DO (set "a=")
cls
call :clear
call :move
if "%errorlevel%"=="1" exit /b
call :draw
goto game
 
 
 
:clear
set area[0]=###############
set area[14]=###############
for /l %%A IN (1 1 13) DO set area[%%A]=#.............#
exit /b
 
:move
set /p dir=<sn.cntrl & echo.>sn.cntrl
if "%dir%"=="Q" (erase sn.cntrl & exit /b 1)
set "tmpX=%snake[0]X%"&set "tmpY=%snake[0]Y%"
if "%dir%"=="D" set /a snake[0]X+=1
if "%dir%"=="W" set /a snake[0]Y-=1
if "%dir%"=="S" set /a snake[0]Y+=1
if "%dir%"=="A" set /a snake[0]X-=1
if defined err[%snake[0]X%][%snake[0]Y%] goto gameover
for /L %%A IN (1 1 %snake.length%) DO (
 set "tmp2X=!snake[%%A]X!"&set "tmp2Y=!snake[%%A]Y!"
 set "err[!tmp2X!][!tmp2Y!]="
 set "snake[%%A]X=!tmpX!"&set "snake[%%A]Y=!tmpY!"
 set "err[!tmpX!][!tmpY!]=1"
 set "tmpX=!tmp2X!"&set "tmpY=!tmp2Y!"
)
if "%snake[0]X%"=="%eatX%" (
 if "%snake[0]Y%"=="%eatY%" (
  call :cepos
  set /a snake.length+=1 
 )
)
if %snake[0]X% LEQ 0  goto gameover
if %snake[0]X% GEQ 14 goto gameover
if %snake[0]Y% LEQ 0  goto gameover
if %snake[0]Y% GEQ 14 goto gameover
exit /b 0
 
:draw
call :insArea area[%eatY%] %eatX% $
call :insArea area[%snake[0]Y%] %snake[0]X% @
for /L %%A IN (1 1 %snake.length%) DO (
 set areaN=area[!snake[%%A]Y!]
 call :insArea !areaN! !snake[%%A]X! +
)
for /L %%A IN (0 1 14) DO echo.!area[%%A]!
exit /b
 
:insArea
set /a pos=%~2+1
set %~1=!%~1:~0,%~2!%~3!%~1:~%pos%!
exit /b 
 
:control
@echo on
mode con cols=50 lines=5
:control[0]
choice /C "wasdq" /N >nul
:control[1]
if "%errorlevel%"=="1" echo.W>sn.cntrl 2>nul|| goto control[1]
if "%errorlevel%"=="2" echo.A>sn.cntrl 2>nul|| goto control[1]
if "%errorlevel%"=="3" echo.S>sn.cntrl 2>nul|| goto control[1]
if "%errorlevel%"=="4" echo.D>sn.cntrl 2>nul|| goto control[1]
if "%errorlevel%"=="5" echo.Q>sn.cntrl 2>nul|| goto control[1]
goto control[0]
 
:gameover
echo.GAME OVER | msg *
erase sn.cntrl
exit
 
:cepos
set /a eatX=(%RANDOM% %% 13) + 1
set /a eatY=(%RANDOM% %% 13) + 1
if defined err[%eatX%][%eatY%] goto cepos
exit /b