Предложить алгоритм, позволяющий найти маршрут из клетки (1,1) в клетку (N,N)

program Pr_3;
 
uses crt;
 
type matrix = array [1..14,1..14] of integer;
 
var
 i,k,j,N,p:byte;
 A,B,u:matrix;
 C:array[1..26,1..2] of integer;
 
{----- нахождение максимального числа из двух ---}
 
function max(A1,A2:integer; var p:byte):integer;
 var
  d:integer;
 begin
  if A1>A2 then d:=A1
   else
    begin
      d:=A2;
      p:=1;
    end;
  max:=d;
 end;
 
{----- вывод первоначальной таблицы на экран -------}
 
procedure vivod(D:matrix);
var i,j:byte;
  begin
    for i:= 1 to N do
     begin
      for j:= 1 to N do
       Write('  ',D[i,j]);
      WriteLn;
     end;
  end;
 
{----- вывод маршрута на экран -------}
 
procedure vivodB(D:matrix);
var i,j:byte;
    h:string;
  begin
    for i:= 1 to N do
     begin
      for j:= 1 to N do
         begin
           case D[i,j] of      {для более наглядного изображения}
            10..99: h:=' ';
            100..999: h:='';
            else  h:='  ';
           end;                                    {вывод самого маршрута}
           if (u[i,j+1]=1) and (j<N) then Write(' ',D[i,j],h,'-') {при переходе между столбцами}
             else Write(' ',D[i,j],h,' ');
         end;
      WriteLn;
      for j:= 1 to N do
        if (u[i+1,j]=0) and (i<N) then Write(' |   ') {при переходе с одной строки на другую}
           else Write('     ');
      WriteLn;
     end;
  end;
 
 
BEGIN
 clrscr;
 repeat               { задаем число N }
  Write('  Введите размерность матрицы (1 - 13): ');
  ReadLn(N);
 until (N<=13) and (N>=1);
 
 randomize;
 
 for i:= 1 to N do    { формирование первоначальной мартицы }
  for j:= 1 to N do
   A[i,j]:=random(10);
 
 writeln;
 writeln(' Первоначальная матрица:');
 writeln;
 vivod(A);    {вывод этой матрицы}
 
 B[1,1]:=A[1,1];    {В - матрица, где храниться максимальная сумма,
                    которую можно получить дойдя от (1.1) до данной ячейки}
 u[1,1]:=0;         {U - матрица, где храниться значение как мы попали в ячейку В:
                    0 -  двигались из соседней сверху ячейки,
                    1 -  двигались из соседней слева ячейки}
 
 for i:=2 to N do   {заполнение первой строки и первого столбца}
  begin             {мы можем двигаться только в одном направлении}
   B[1,i]:=A[1,i]+B[1,i-1];
   u[1,i]:=1;
   B[i,1]:=A[i,1]+B[i-1,1];
   u[i,1]:=0;
  end;
 
  for i:= 2 to N do    {заполнение матрицы В и U}
    for j:= 2 to N do
      begin
       p:=0;
       B[i,j]:=A[i,j]+max(B[i-1,j],B[i,j-1],p);
       u[i,j]:=p;
      end;
 
 WriteLn;
 WriteLn(' Максимальная сумма в каждой ячейке, которую можно получить дойдя до нее,');
 Writeln(' и путь получения этой суммы:');
 writeln;
 vivodB(B);           {вывод значений В и пути заполнения В}
 
 i:=N;
 k:=N;
 j:=2*N-1;  {минимальное количество точек}
 C[1,1]:=1;  {G - координаты маршрута пути}
 C[1,2]:=1;  {первоначальная точка (1.1)}
 
 while (i<>1) or (k<>1) do {заполнение C, начиная с последней точки }
  begin
   C[j,1]:=i;
   C[j,2]:=k;
   if i=1 then Dec(k) {если первая строчка, то идем по столбцам}
          else
            if k=1 then Dec(i) {если первый столбец, то идем по строчкам}
                   else
                    if max(b[i-1,k],b[i,k-1],p)=b[i,k-1] then Dec(k) {если максимальное число слева, то идем по строчке}
                                                         else Dec(i);{иначе идем по столбцу}
   Dec(j);
  end;
 
 for i:= 1 to N do {"обнуление" матрицы U}
  for j:= 1 to N do
   u[i,j]:=3;
 
 for i:=1 to 2*N-1 do {заполнение пути следования}
  if C[i,1]=C[i+1,1] then u[C[i,1],C[i,2]+1]:=1 {если одинаковый индекс строки, то 1}
    else u[C[i,1]+1,C[i,2]]:=0;{если одинаковый индекс столбца, то 0}
 
 WriteLn;
 writeln(' Путь следования в матрице:');
 WriteLn;
 vivodB(A);{вывод первоначальной матрицы с маршрутом следования}
 
 WriteLn;
 write(' Сам маршрут: ');
 Write(C[1,1],',',C[1,2]);
 for i:=2 to 2*N-1 do
  Write(' -> ',C[i,1],',',C[i,2]);
 
 ReadKey;
end.