Перемещение камеры по сцене для Opengl на Lazarus.

unit main;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, ExtCtrls, 
  OpenGLContext, gl, glu, LCLType, ComCtrls, Types, Math;
 
type
 
  { TOGLForm }
 
  TOGLForm = class(TForm)
    GLBox: TOpenGLControl;
    procedure FormCreate(Sender: TObject);
    procedure GLBoxMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
    procedure GLBoxMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
    procedure GLBoxMouseUp(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
    procedure GLBoxMouseWheel(Sender: TObject; Shift: TShiftState; WheelDelta: Integer; MousePos: TPoint; var Handled: Boolean);
    procedure GLBoxPaint(Sender: TObject);
  private
  procedure CreateBase;
  procedure CreateNet;
  procedure Draw;
  public
  down,XS,YS,dx,dy,dz:integer;
  end;
 
var
  OGLForm: TOGLForm;
 
implementation
 
{$R *.lfm}
 
{ TOGLForm }
var xf,yf,zf,x0,y0,z0:double;
 
 
procedure TOGLForm.FormCreate(Sender: TObject);
begin
  zf:=200;xf:=-200;yf:=0;  //--Камера
  x0:=0;y0:=0;z0:=0;       //--Цель
end;
 
//--Нахождение угла (+-180° по x,y)
function Angle(x,y:double):double;
begin
if (Abs(x)<0.00000001) and (y>0) then begin Result:=90;exit;end;
if (Abs(x)<0.00000001) and (y<0) then begin Result:=-90;exit;end;
if (Abs(y)<0.00000001) and (x>0) then begin Result:=0;exit;end;
if (Abs(y)<0.00000001) and (x<0) then begin Result:=180;exit;end;
if (x>0) and (y>0) then begin Result:=arctan(y/x)*180/PI;exit;end;
if (x>0) and (y<0) then begin Result:=arctan(y/x)*180/PI;exit;end;
if (x<0) and (y>0) then begin Result:=180+arctan(y/x)*180/PI;exit;end;
if (x<0) and (y<0) then begin Result:=-180+arctan(y/x)*180/PI;exit;end;
end;
 
//--Нажатие кнопки мыши
procedure TOGLForm.GLBoxMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
XS:=X;YS:=Y;
if Button = mbLeft  then down:=1;
if Button = mbRight then down:=2;
if (Button = mbRight) and (ssCtrl in Shift) then down:=3;
end;
 
//--Колесо мыши - приближение/удаление
procedure TOGLForm.GLBoxMouseWheel(Sender: TObject; Shift: TShiftState; WheelDelta: Integer; MousePos: TPoint; var Handled: Boolean);
var r,r2,rp,rp2,xa,ya,za:double;
begin
r:=Sqrt((xf-x0)*(xf-x0)+(yf-y0)*(yf-y0)+zf*zf);
if WheelDelta<0 then rp:=r+5 else rp:=r-5;
r2:=r*r;
rp2:=rp*rp;
xa:=Sqrt((xf-x0)*(xf-x0)*rp2/r2);
ya:=Sqrt((yf-y0)*(yf-y0)*rp2/r2);
za:=Sqrt(zf*zf*rp2/r2);
xf:=xa*sign(xf-x0)+x0;
yf:=ya*sign(yf-y0)+y0;
zf:=za*sign(zf);
Draw;
end;
 
//--Движение мыши
procedure TOGLForm.GLBoxMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
var teta,dt,dtx,dty,x1,y1,r,fi,fiz:Extended;
//label 1;
begin
//---Поворот вокруг прямой Ax+By+C=0 (подъём, фи,тэта)
if down=1 then
   begin
   dt:=YS-Y;
   fiz:=Angle(xf-x0,yf-y0);
   r:=Sqrt((xf-x0)*(xf-x0)+(yf-y0)*(yf-y0)+zf*zf);
   teta:=arccos(zf/r)*180/PI;
   teta:=teta+dt/2;
   if (teta<0) or (teta>90) then exit;
   xf:=r*cos(fiz*PI/180)*sin(teta*PI/180)+x0;
   yf:=r*sin(fiz*PI/180)*sin(teta*PI/180)+y0;
   zf:=r*cos(teta*PI/180);
   YS:=Y;
   Draw;exit;
   end;
//---Поворот вокруг оси Z (фи)
if down=2 then
   begin
   dt:=XS-X;dt:=dt/5;
   fiz:=dt*PI/180;
   x1:=(xf-x0)*cos(fiz)-(yf-y0)*sin(fiz);
   y1:=(xf-x0)*sin(fiz)+(yf-y0)*cos(fiz);
   xf:=x1+x0;
   yf:=y1+y0;
   Draw;
   XS:=X;
   exit;
   end;
//---Смещение
if down=3 then
   begin
   dt:=XS-X;dt:=dt/5;
   fi:=Angle(xf-x0,yf-y0);
   dtx:=-cos((fi-90)*PI/180)*dt;dty:=-sin((fi-90)*PI/180)*dt;
   xf:=xf+dtx;
   yf:=yf+dty;
   x0:=x0+dtx;
   y0:=y0+dty;
   Draw;
   XS:=X;
   exit;
   end;
end;
 
//--Отжатие мыши
procedure TOGLForm.GLBoxMouseUp(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
down:=0;
end;
 
//--Рисовать
procedure TOGLForm.GLBoxPaint(Sender: TObject);
begin
Draw;
end;
 
//--Задать параметры рисования, нарисовать "пол"
procedure TOGLForm.CreateBase;
begin
glClearColor(0.8,0.9,1.0,1);
 
glCullFace(GL_FRONT_AND_BACK);
glEnable(GL_BLEND);
glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
glShadeModel(GL_SMOOTH);
glHint(GL_POLYGON_SMOOTH_HINT, GL_FASTEST);
glEnable(GL_POLYGON_SMOOTH);
glHint(GL_POINT_SMOOTH_HINT, GL_FASTEST);
glEnable(GL_POINT_SMOOTH);
glHint(GL_LINE_SMOOTH_HINT, GL_FASTEST);
glEnable(GL_LINE_SMOOTH);
glDisable( GL_DEPTH_TEST );
glEnable( GL_ALPHA_TEST );
glClear(GL_COLOR_BUFFER_BIT);
 
glMatrixMode(gl_Projection);
glLoadIdentity;
 
gluPerspective(45,Width/Height, 0.1, 1000);
glViewport(0,0,Width,Height);
gluLookAt(xf,yf,zf,x0,y0,z0,0,0,1);
 
glBegin(gl_Quads);
glColor3f(0.3,0.5,0);
glVertex3f(200,200,0);
glVertex3f(200,-200,0);
glVertex3f(-200,-200,0);
glVertex3f(-200,200,0);
glEnd;
end;
 
//--Рисовать сетку
procedure TOGLForm.CreateNet;
var i,j:integer;
begin
glColor3f(1,1,0);
glLineWidth(1.0);
glBegin(gl_Lines);
for i:=0 to 10 do
   begin
   glVertex3f(-50,i*10-50,0);glVertex3f(50,i*10-50,0);
   glVertex3f(i*10-50,-50,0);glVertex3f(i*10-50,50,0);
   end;
glEnd;
end;
 
//--Рисовать
procedure TOGLForm.Draw;
begin
CreateBase;
CreateNet;
 
GLBox.SwapBuffers;
end;
 
end.