экспорт из access в word Delphi

// uses DB;
 
procedure DsMoveTo(dts: TDataSet; index: integer);
begin
  dts.MoveBy(index-dts.RecNo);
end;
 
function DsNotEmpty(inSet: TDataSet): boolean;
begin
  if not inSet.Active then Result:=false else
  Result := Not (inSet.Bof and inSet.eof);
end;
 
procedure DataSetToMSWord(Ds:TDataSet; WordApp,WordDocument:variant);
var i,j,p,c:integer; table: Variant;
begin
  if not DsNotEmpty(ds) then begin
    ShowMessage('Нельзя вывести отчет в Word, DataSet пустой');
    exit;
  end;
  WordApp.visible:=false;
  c:= Ds.RecordCount+1;
  table:=WordDocument.tables.add(
    WordApp.Selection.Range,
    NumRows:=c, // тут ширина и колво-колонок должно быть уже известно.
    NumColumns:=Ds.FieldCount,
    DefaultTableBehavior:=1,
    AutoFitBehavior:=1
  );
  for i:=1 to Ds.FieldCount do begin
     table.columns.item(i).PreferredWidth:=50;
     table.cell(1,i).select;
     WordApp.Selection.typetext( Ds.Fields[i-1].DisplayLabel );
  end;
  table.rows.item(1).select;
  WordApp.Selection.Font.Bold:=true;
  WordApp.Selection.Font.Size:=12;
  Ds.DisableControls;
  p:=Ds.RecNo;
  Ds.First;
  for i:=2 to c do begin
    for j:=1 to Ds.FieldCount do begin
      table.cell(i,j).select;
      WordApp.Selection.typetext(
        Ds.Fields[j-1].AsString
      );
    end;
    Ds.Next;
  end;
  DsMoveTo(ds,p);
  Ds.EnableControls;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var WordApp,doc: Variant;
begin
  WordApp:=CreateOleObject('Word.Application');
  doc:=WordApp.Documents.Add;
   // вывод датасета в Word
  DataSetToMSWord(ADOTable1, WordApp, doc);
  WordApp.Visible:=true;
end;