USB барометр

EnableExplicit
 
XIncludeFile "HID_Module.pbi"
XIncludeFile "Form.pbf"
 
#USB_PID=$0802
#USB_VID=$2015
 
Enumeration
  #Im_Usb_d
  #Im_Usb_e
  #Im_Sun
  #Im_Sun_Cloudy
  #Im_Cloud
  #Im_Rain
EndEnumeration
 
Structure HID_Data
  ID.a
  Thermo.w
  Pressure.l
  Reserved.a[2]
EndStructure
 
Global gDeviceHandle=0, gNumActiveImage=#Im_Usb_d
Define Event
 
Procedure.d Altitude(PressPasc.d) ; Расчет высоты над уровнем моря.
  ProcedureReturn (1 - Pow(PressPasc / 101325, 0.190294)) * 44330
EndProcedure
 
Procedure ChangeImage(PressHg.u)
  Protected String.s, Image=-1
  
  If PressHg>=770
    Image=#Im_Sun
    String="Ясно"
  ElseIf PressHg>=750
    Image=#Im_Sun_Cloudy
    String="Малооблачно"
  ElseIf PressHg>=740
    Image=#Im_Cloud
    String="Облачно"
  Else
    Image=#Im_Rain
    String="Облачно, возможны осадки"
  EndIf
  
  If gNumActiveImage<>Image And Image<>-1
    gNumActiveImage=Image
    SetGadgetState(#Image_0, ImageID(Image))
    GadgetToolTip(#Image_0, String)
  EndIf
  
EndProcedure;
 
Procedure GetInfo(hHID)
  Protected Info.HID_Data, PressHg.d
  
  If HID::GetFeature(hHID, @Info, SizeOf(HID_Data))=#True
    
    PressHg=Info\Pressure * 0.0075004
    SetGadgetText(#Text_1, StrD(PressHg, 1))
    SetGadgetText(#Text_4, StrD(Info\Pressure / 100, 1))
    SetGadgetText(#Text_7, StrD(Altitude(Info\Pressure), 1))
    SetGadgetText(#Text_10, StrF(Info\Thermo / 10, 1))
    
    ChangeImage(PressHg)
  EndIf
  
EndProcedure
 
Procedure Timer1()
  Static Old_Test
  Protected Test
  
  Test=HID::TestDevice(#USB_PID, #USB_VID)
  If Test<>Old_Test
    Old_Test=Test
    If Test
      gDeviceHandle=HID::OpenDevice(#USB_PID, #USB_VID)
      SetGadgetState(#Image_0, ImageID(#Im_Usb_e))
      GadgetToolTip(#Image_0, "Устройство подключено")
      gNumActiveImage=#Im_Usb_e
    Else
      HID::CloseDevice(gDeviceHandle)
      gDeviceHandle=0
      SetGadgetState(#Image_0, ImageID(#Im_Usb_d))
      GadgetToolTip(#Image_0, "Устройство не подключено")
      gNumActiveImage=#Im_Usb_d
      SetGadgetText(#Text_1, "")
      SetGadgetText(#Text_4, "")
      SetGadgetText(#Text_7, "")
      SetGadgetText(#Text_10, "")
    EndIf
  EndIf
  
  If Test And gDeviceHandle
    GetInfo(gDeviceHandle)
  EndIf
  
EndProcedure
 
; Загрузка картинок из памяти.
CatchImage(#Im_Usb_d, ?Usb_d)
CatchImage(#Im_Usb_e, ?Usb_e)
CatchImage(#Im_Sun, ?Sun)
CatchImage(#Im_Sun_Cloudy, ?Sun_Cloudy)
CatchImage(#Im_Cloud, ?Cloud)
CatchImage(#Im_Rain, ?Rain)
 
HID::HID_Init() ; Инициализация USB HID библиотеки
 
OpenWindow_0()
SetGadgetState(#Image_0, ImageID(#Im_Usb_d))
Timer1()
 
AddWindowTimer(#Window_0, 0, 1000)
BindEvent(#PB_Event_Timer, @Timer1(), #Window_0, 0)
 
Repeat ; Главный цикл программы.
  Event = WaitWindowEvent()
Until Event = #PB_Event_CloseWindow
 
HID::HID_End()
 
End
 
DataSection
  Usb_d:
  IncludeBinary "Files\usb_d.ico"
  Usb_e:
  IncludeBinary "Files\usb_e.ico"
  Sun:
  IncludeBinary "Files\Sun.ico"
  Sun_Cloudy:
  IncludeBinary "Files\Sun_Cloudy.ico"
  Cloud:
  IncludeBinary "Files\Cloud.ico"
  Rain:
  IncludeBinary "Files\Rain.ico"
EndDataSection